Update python2-dispass-git to v20130526

Includes updates for the new pacman version (pkgver function) and
updated files for DisPass (zsh completion).

1 files changed, 25 insertions, 26 deletions

diff --git a/python2-dispass-git/PKGBUILD b/python2-dispass-git/PKGBUILD
index 87c5d4e..3518022 100644
--- a/python2-dispass-git/PKGBUILD
+++ b/python2-dispass-git/PKGBUILD
@@ -1,46 +1,45 @@
-# Maintainer: Tom Willemsen <tom@ryuslash.org>
+# -*- mode: sh; -*-
+# Maintainer: Tom Willemse <tom@ryuslash.org>
 
-python=python2
-name=DisPass
+_python=python2
+_name=DisPass
 
-pkgname=$python-dispass-git
-pkgver=20120807
+pkgname=$_python-dispass-git
+pkgver=20130526
 pkgrel=1
 pkgdesc="Generate and disperse/dispell passwords"
 depends=('python2')
-makedepends=('python2-distribute')
+makedepends=('python2-distribute' 'git')
+optdepends=('tk: for gdispass')
 arch=('any')
+source=("git://github.com/babab/$_name.git")
 url="http://dispass.babab.nl/"
 license=("custom:ISC")
 conflicts=(python2-dispass)
+md5sums=('SKIP')
 
-_gitroot=git://github.com/babab/DisPass.git
-_gitname=master
+pkgver() {
+    cd "$srcdir"/"$_name"
+    git log -1 --pretty=format:"%cd" --date=short | sed s/-//g
+}
 
 build() {
-    cd "$srcdir"
-
-    if [ ! -d $name ]; then
-        git clone $_gitroot $name;
-        cd $name
-    else
-        cd $name
-        git pull origin $_gitname
-    fi
-
-    python2 setup.py build || return 1
+    cd "$srcdir"/"$_name"
+    $_python setup.py build || return 1
 }
 
 package() {
-    cd "$srcdir/$name"
-    python2 setup.py install --root="$pkgdir"
+    cd "$srcdir/$_name"
+    $_python setup.py install --root="$pkgdir"
 
-    install -Dm644 "${srcdir}/${name}/skel/dot.dispass" \
-        "${pkgdir}/etc/skel/.dispass"
-    install -Dm644 "${srcdir}/${name}/dispass.1" \
+    install -Dm644 "${srcdir}/${_name}/skel/labelfile" \
+        "${pkgdir}/etc/skel/.dispass/labels"
+    install -Dm644 "${srcdir}/${_name}/dispass.1" \
         "${pkgdir}/usr/share/man/man1/dispass.1"
-    install -Dm644 "${srcdir}/${name}/LICENSE" \
+    install -Dm644 "${srcdir}/${_name}/LICENSE" \
         "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
-    install -Dm644 "${srcdir}/${name}/README.rst" \
+    install -Dm644 "${srcdir}/${_name}/README.rst" \
         "${pkgdir}/usr/share/doc/${pkgname}/README.rst"
+    install -Dm644 "${srcdir}/${_name}/zsh/_dispass" \
+        "${pkgdir}/usr/share/zsh/site-functions/_dispass"
 }