freedesktop: Add missing file

1 files changed, 45 insertions, 0 deletions

diff --git a/oni/home/services/freedesktop.scm b/oni/home/services/freedesktop.scm
new file mode 100644
index 0000000..8b29fc6
--- /dev/null
+++ b/oni/home/services/freedesktop.scm
@@ -0,0 +1,45 @@
+(define-module (oni home services freedesktop)
+  #:use-module (gnu services configuration)
+  #:use-module (gnu packages freedesktop)
+  #:use-module (gnu home services)
+  #:use-module (gnu home services utils)
+  #:use-module (gnu home services shepherd)
+  #:use-module (guix packages)
+  #:use-module (guix gexp)
+
+  #:export (home-udiskie-service-type
+            home-udiskie-configuration))
+
+(define-configuration home-udiskie-configuration
+  (package
+    (package udiskie)
+    "Package to use for setting udiskie"))
+
+(define (add-udiskie-packages config)
+  (list (home-udiskie-configuration-package config)))
+
+(define (home-udiskie-shepherd-service config)
+  (list
+   (shepherd-service
+    (documentation "Start udiskie")
+    (provision '(udiskie))
+    (auto-start? #t)
+    (start
+     #~(make-forkexec-constructor
+        (list #$(file-append (home-udiskie-configuration-package config) "/bin/udiskie"))
+        #:log-file (format #f "~a/.local/var/log/udiskie.log" (getenv "HOME"))))
+    (stop #~(make-kill-destructor)))))
+
+(define home-udiskie-service-type
+  (service-type
+   (name 'home-udiskie)
+   (extensions
+    (list (service-extension
+           home-profile-service-type
+           add-udiskie-packages)
+          (service-extension
+           home-shepherd-service-type
+           home-udiskie-shepherd-service)))
+   (compose identity)
+   (default-value (home-udiskie-configuration))
+   (description "Install and configure udiskie.")))