Add snippets for ‘oni-php’

4 files changed, 166 insertions, 0 deletions

diff --git a/oni-php/Cask b/oni-php/Cask
new file mode 100644
index 0000000..6011891
--- /dev/null
+++ b/oni-php/Cask
@@ -0,0 +1,19 @@
+(source gnu)
+(source melpa)
+
+(package-file "./oni-php.el")
+
+(depends-on "php-mode")
+(depends-on "oni-yasnippet" :git "../" :files ("oni-yasnippet.el"))
+(depends-on "oni-flycheck" :git "../" :files ("oni-flycheck.el"))
+(depends-on "oni-company" :git "../" :files ("oni-company.el"))
+(depends-on "oni-fci" :git "../" :files ("oni-fci.el"))
+(depends-on "ggtags")
+(depends-on "fic-mode")
+(depends-on "hydra")
+(depends-on "company-php")
+(depends-on "phpcbf")
+
+(files
+ "*.el"
+ ("snippets" "./snippets/*"))
diff --git a/oni-php/oni-php.el b/oni-php/oni-php.el
new file mode 100644
index 0000000..ed7fbb9
--- /dev/null
+++ b/oni-php/oni-php.el
@@ -0,0 +1,126 @@
+;;; oni-php.el --- PHP Configuration                 -*- lexical-binding: t; -*-
+
+;; Copyright (C) 2019  Tom Willemse
+
+;; Author: Tom Willemse <tom@ryuslash.org>
+;; Keywords: local
+;; Version: 20190827234741
+;; Package-Requires: (php-mode oni-yasnippet oni-flycheck oni-company oni-fci ggtags fic-mode hydra company-php phpcbf)
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; My PHP mode configuration. Includes rules for aligning variables according to
+;; the WordPress coding standards.
+
+;;; Code:
+
+(require 'align)
+(require 'company)
+(require 'php-mode)
+(require 'whitespace)
+(require 'yasnippet)
+
+(defconst oni-php-root
+  (file-name-directory
+   (or load-file-name
+       (buffer-file-name)))
+  "The directory where ‘oni-php’ was loaded from.")
+
+(defconst oni-php-snippets-dir
+  (expand-file-name "snippets" oni-php-root)
+  "The directory where ‘oni-php’ stores its snippets.")
+
+;;;###autoload
+(defun oni-php-snippets-initialize ()
+  "Initialize the snippets for ‘oni-php’."
+  (when (boundp 'yas-snippet-dirs)
+    (add-to-list 'yas-snippet-dirs oni-php-snippets-dir))
+  (yas-load-directory oni-php-snippets-dir))
+
+(defun oni-php--set-require-final-newline ()
+  "Set `require-final-newline' to t.
+This is necessary because the PHP mode configuration sets this to
+nil for some reason."
+  (setq require-final-newline t))
+
+(defun oni-php--whitespace-mode ()
+  "Enable whitespace mode with only tabs showing."
+  (setq-local whitespace-style '(face tabs))
+  (whitespace-mode))
+
+(defhydra php-mode-hydra (:color blue)
+  ("a" align-current "Align current selection"))
+
+(add-hook 'php-mode-hook #'oni-php--set-require-final-newline)
+(add-hook 'php-mode-hook #'oni-php--whitespace-mode)
+(add-hook 'php-mode-hook 'company-mode)
+(add-hook 'php-mode-hook 'electric-indent-local-mode)
+(add-hook 'php-mode-hook 'electric-pair-local-mode)
+(add-hook 'php-mode-hook 'fci-mode)
+(add-hook 'php-mode-hook 'fic-mode)
+(add-hook 'php-mode-hook 'flycheck-mode)
+(add-hook 'php-mode-hook 'ggtags-mode)
+(add-hook 'php-mode-hook 'phpcbf-enable-on-save)
+
+(with-eval-after-load 'company
+  (add-to-list 'company-backends 'company-ac-php-backend))
+
+(define-key php-mode-map (kbd "C-c m") #'php-mode-hydra/body)
+
+;; In PHP code it's nice to have any ~=>~ aligned.
+
+;; <?php
+;; array(
+;;     'foo'  => 'bar',
+;;     'frob' => 'baz'
+;; );
+;; ?>
+
+(add-to-list 'align-rules-list
+             `(php-array-arrow
+               (regexp . ,(rx any (group (zero-or-more whitespace)) "=>" any))
+               (group . (1))
+               (modes . '(php-mode web-mode))
+               (repeat . t)))
+
+;; The WordPress coding standards specify that multiple assignments
+;; should have their assignment operators aligned.
+
+;; <?php
+;; $variable          = "value";
+;; $other_variable    = "other value";
+;; $one_more_variable = "one more variable";
+
+(add-to-list 'align-rules-list
+             `(php-assignment-equals
+               (regexp . ,(rx any (group (zero-or-more whitespace)) "="
+                              (zero-or-more whitespace) any))
+               (group . (1))
+               (modes . '(php-mode web-mode))
+               (repeat . t)))
+
+;;;###autoload
+(with-eval-after-load 'php-mode
+  (with-eval-after-load 'yasnippet
+    (oni-php-snippets-initialize)))
+
+;;;###autoload(with-eval-after-load 'php-mode (require 'oni-php))
+;;;###autoload(add-to-list 'auto-mode-alist '("\\.inc\\'" . php-mode))
+;;;###autoload(add-to-list 'auto-mode-alist '("\\.module\\'" . php-mode))
+;;;###autoload(with-eval-after-load 'grep (add-to-list 'grep-files-aliases '("php" . "*.php *.inc *.module")))
+
+(provide 'oni-php)
+;;; oni-php.el ends here
diff --git a/oni-php/snippets/php-mode/function b/oni-php/snippets/php-mode/function
new file mode 100644
index 0000000..ab4cf2c
--- /dev/null
+++ b/oni-php/snippets/php-mode/function
@@ -0,0 +1,8 @@
+# -*- mode: snippet; require-final-newline: nil -*-
+# name: function
+# key: function
+# --
+function $1($2)
+{
+    $0
+}
\ No newline at end of file
diff --git a/oni-php/snippets/php-mode/wpheader.php b/oni-php/snippets/php-mode/wpheader.php
new file mode 100644
index 0000000..2c70f93
--- /dev/null
+++ b/oni-php/snippets/php-mode/wpheader.php
@@ -0,0 +1,13 @@
+# -*- mode: snippet; require-final-newline: nil -*-
+# name: WP Plugin Header
+# key: header
+# --
+/*
+ * Plugin Name: $1
+ * Plugin URI: $2
+ * Description: $3
+ * Version: ${4:1.0}
+ * Author: ${5:Tom Willemse}
+ * Author URI: ${6:https://ryuslash.org}
+ * License: ${7:GPLv2}
+ */
\ No newline at end of file