Tom Willemse
2268dfc27a
In the Groovy used with Jenkins it seems quite common for there to be top-level functions that aren't explicitly in classes (they still are implicitly).
100 lines
3.4 KiB
EmacsLisp
100 lines
3.4 KiB
EmacsLisp
;;; oni-groovy.el --- Configuration for Groovy mode -*- lexical-binding: t; -*-
|
||
|
||
;; Copyright (C) 2019 Tom Willemse
|
||
|
||
;; Author: Tom Willemse <tom@ryuslash.org>
|
||
;; Keywords: local
|
||
;; Version: 2023.0505.164419
|
||
;; Package-Requires: (groovy-mode oni-embrace oni-smartparens groovy-imports rainbow-delimiters jenkinsfile-mode)
|
||
|
||
;; This program is free software; you can redistribute it and/or modify
|
||
;; it under the terms of the GNU General Public License as published by
|
||
;; the Free Software Foundation, either version 3 of the License, or
|
||
;; (at your option) any later version.
|
||
|
||
;; This program is distributed in the hope that it will be useful,
|
||
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;; GNU General Public License for more details.
|
||
|
||
;; You should have received a copy of the GNU General Public License
|
||
;; along with this program. If not, see <https://www.gnu.org/licenses/>.
|
||
|
||
;;; Commentary:
|
||
|
||
;; My ‘groovy-mode’ configuration.
|
||
|
||
;;; Code:
|
||
|
||
(require 'groovy-imports)
|
||
(require 'groovy-mode)
|
||
(require 'smartparens)
|
||
|
||
(defun oni-groovy--auto-fill-mode ()
|
||
"Enable ‘auto-fill-mode’ only for comments."
|
||
(setq-local comment-auto-fill-only-comments t)
|
||
(auto-fill-mode))
|
||
|
||
(defconst oni-groovy--regex-defun-start
|
||
(rx line-start
|
||
(minimal-match (zero-or-more space))
|
||
"def "
|
||
(minimal-match (one-or-more alnum))
|
||
(minimal-match (zero-or-more space))
|
||
"("))
|
||
|
||
(defun oni-groovy-beginning-of-defun ()
|
||
(interactive)
|
||
(when (not (region-active-p))
|
||
(push-mark))
|
||
(let ((case-fold-search t))
|
||
(when (re-search-backward oni-groovy--regex-defun-start nil t)
|
||
t)))
|
||
|
||
(defun oni-groovy-end-of-defun ()
|
||
(interactive)
|
||
(when (not (region-active-p))
|
||
(push-mark))
|
||
(let ((case-fold-search t))
|
||
(when (or (looking-at oni-groovy--regex-defun-start)
|
||
(re-search-backward oni-groovy--regex-defun-start nil t))
|
||
(search-forward "{")
|
||
(forward-char -1)
|
||
(forward-sexp)
|
||
(forward-line))))
|
||
|
||
(defun oni-groovy-setup-defun-navigation ()
|
||
(setq-local beginning-of-defun-function #'oni-groovy-beginning-of-defun
|
||
end-of-defun-function #'oni-groovy-end-of-defun))
|
||
|
||
(defun oni-groovy-setup-smartparens ()
|
||
(sp-local-pair '(groovy-mode) "/" "/"))
|
||
|
||
(define-key groovy-mode-map (kbd "M-I") 'groovy-imports-add-import-dwim)
|
||
|
||
(add-hook 'groovy-mode-hook #'oni-groovy-setup-defun-navigation)
|
||
(add-hook 'groovy-mode-hook 'display-fill-column-indicator-mode)
|
||
(add-hook 'groovy-mode-hook 'electric-indent-local-mode)
|
||
(add-hook 'groovy-mode-hook 'groovy-imports-scan-file)
|
||
(add-hook 'groovy-mode-hook 'oni-groovy--auto-fill-mode)
|
||
(add-hook 'groovy-mode-hook 'oni-groovy-setup-smartparens)
|
||
(add-hook 'groovy-mode-hook 'rainbow-delimiters-mode)
|
||
(add-hook 'groovy-mode-hook 'smartparens-mode)
|
||
|
||
;;;###autoload
|
||
(add-to-list 'auto-mode-alist `(,(rx ".pipeline" string-end) . jenkinsfile-mode))
|
||
|
||
;;;###autoload
|
||
(with-eval-after-load 'grep
|
||
(add-to-list 'grep-files-aliases '("groovy" . "*.groovy *.pipeline Jenkinsfile")))
|
||
|
||
(setf (alist-get "Functions" groovy-imenu-regexp nil nil #'string=)
|
||
(list (rx line-start "def"
|
||
(minimal-match (one-or-more whitespace))
|
||
(group alpha (minimal-match (zero-or-more alphanumeric)))
|
||
(minimal-match (zero-or-more whitespace))
|
||
"(")
|
||
1))
|
||
|
||
(provide 'oni-groovy)
|
||
;;; oni-groovy.el ends here
|