313 lines
11 KiB
EmacsLisp
313 lines
11 KiB
EmacsLisp
;;; oni-org.el --- Org mode configuration -*- lexical-binding: t; -*-
|
||
|
||
;; Copyright (C) 2019 Tom Willemse
|
||
|
||
;; Author: Tom Willemse <tom@ryuslash.org>
|
||
;; Keywords: local
|
||
;; Version: 2020.0408.205648
|
||
;; Package-Requires: (oni-yasnippet oni-alert oni-hydra org-plus-contrib org-bullets org-edna)
|
||
|
||
;; This program is free software; you can redistribute it and/or modify
|
||
;; it under the terms of the GNU General Public License as published by
|
||
;; the Free Software Foundation, either version 3 of the License, or
|
||
;; (at your option) any later version.
|
||
|
||
;; This program is distributed in the hope that it will be useful,
|
||
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;; GNU General Public License for more details.
|
||
|
||
;; You should have received a copy of the GNU General Public License
|
||
;; along with this program. If not, see <https://www.gnu.org/licenses/>.
|
||
|
||
;;; Commentary:
|
||
|
||
;; Configuration for `org-mode'.
|
||
|
||
;;; Code:
|
||
|
||
(require 'hydra)
|
||
(require 'ob)
|
||
(require 'ol-man)
|
||
(require 'org)
|
||
(require 'org-capture)
|
||
(require 'org-clock)
|
||
(require 'org-edna)
|
||
(require 'org-habit)
|
||
(require 'subr-x)
|
||
(require 'yasnippet)
|
||
|
||
(defconst oni-org-root
|
||
(file-name-directory
|
||
(or load-file-name
|
||
(buffer-file-name)))
|
||
"The directory where ‘oni-org’ was loaded from.")
|
||
|
||
(defconst oni-org-snippets-dir
|
||
(expand-file-name "snippets" oni-org-root)
|
||
"The directory where ‘oni-org’ stores its snippets.")
|
||
|
||
(defun oni-org-expand-to-home (file-name)
|
||
"Expand FILE-NAME to the base directory for that system.
|
||
The base for all org files on Windows is u:/, but on my linux
|
||
installs it will always be ~."
|
||
(let ((base-dir "~"))
|
||
(expand-file-name file-name base-dir)))
|
||
|
||
(defun oni-org-setup-prettify-symbols-mode ()
|
||
"Set up prettify symbols mode for org mode."
|
||
(when (member "Ionicons" (font-family-list))
|
||
(setq-local prettify-symbols-alist
|
||
'(("[ ]" . #xf372)
|
||
("[X]" . #xf374)))
|
||
(set-face-attribute 'org-checkbox nil :family "Ionicons")
|
||
(prettify-symbols-mode)))
|
||
|
||
(defun oni-org-heading-has-predecessor-p ()
|
||
"Determine if the heading at point has any predecessors.
|
||
Only tasks of a level greater than 3 are considered. A task has a
|
||
predecessor if there is a non-DONE sibling defined before it."
|
||
(let ((point (point)))
|
||
(save-excursion
|
||
(org-backward-heading-same-level 1 :invisible-ok)
|
||
(seq-let [level _ keyword] (org-heading-components)
|
||
(not (or (< level 3)
|
||
(= point (point))
|
||
(member keyword org-done-keywords)))))))
|
||
|
||
(defun oni-org-looking-for-tag-p (tag)
|
||
"Return t if we're currently looking for TAG in an agenda."
|
||
(and (eql 'org-tags-view (car org-agenda-redo-command))
|
||
(string-match-p (rx-to-string `(and word-start ,tag word-end))
|
||
org-agenda-query-string)))
|
||
|
||
(defun oni-org-next-heading-position ()
|
||
"Get the position of the next Org heading."
|
||
(or (ignore-errors
|
||
(org-forward-element)
|
||
(point))
|
||
(point-max)))
|
||
|
||
(defun oni-org-skip-tasks ()
|
||
"Skip over tasks I don't want to see right now.
|
||
Tasks being skipped over include ones with the \"ex\" tag and
|
||
ones that have a predecessor."
|
||
(let ((tags (org-get-tags (point))))
|
||
(when (or (and (not (oni-org-looking-for-tag-p "ex"))
|
||
(member "ex" tags))
|
||
(oni-org-heading-has-predecessor-p))
|
||
(oni-org-next-heading-position))))
|
||
|
||
;;;###autoload
|
||
(defun oni-org-snippets-initialize ()
|
||
"Initialize the snippets for ‘oni-org’."
|
||
(when (boundp 'yas-snippet-dirs)
|
||
(add-to-list 'yas-snippet-dirs oni-org-snippets-dir t))
|
||
(yas-load-directory oni-org-snippets-dir))
|
||
|
||
(defun oni-org-delete-frame-once ()
|
||
"Run `delete-frame'.
|
||
|
||
After running it once remove it from `org-capture-after-finalize-hook'."
|
||
(delete-frame)
|
||
(remove-hook 'org-capture-after-finalize-hook 'oni-org-delete-frame-once))
|
||
|
||
(defun oni-org-run-capture-in-dedicated-frame ()
|
||
"Run `org-capture' in a dedicated frame."
|
||
(with-selected-frame (make-frame '((minibuffer)))
|
||
(org-capture nil "t")
|
||
(delete-other-windows)
|
||
(setf (frame-width) 80)
|
||
(setf (frame-height) 24)
|
||
(add-hook 'org-capture-after-finalize-hook 'oni-org-delete-frame-once)))
|
||
|
||
(defun oni-org-maybe-change-todo-state (current-state)
|
||
"Change the state of the current task to in-progress CURRENT-STATE is todo."
|
||
(if (string= current-state "TODO")
|
||
"IN-PROGRESS"
|
||
current-state))
|
||
|
||
;;;###autoload
|
||
(defun oni-org-open-index ()
|
||
"Open the index of my org-based personal wiki."
|
||
(interactive)
|
||
(find-file (oni-org-expand-to-home "documents/gtd/index.org")))
|
||
|
||
(defun oni-org-color-for (object)
|
||
"Generate a hex color by taking the first 6 characters of OBJECT’s MD5 sum."
|
||
(format "#%s" (substring (md5 object) 0 6)))
|
||
|
||
(defun oni-org-generate-todo-keyword-faces ()
|
||
"Create faces for all todo keywords in the current buffer."
|
||
(when-let ((keywords (cl-remove-if (lambda (tag) (assoc tag org-todo-keyword-faces))
|
||
org-todo-keywords-1)))
|
||
(append org-todo-keyword-faces
|
||
(mapcar (lambda (keyword) (cons keyword (oni-org-color-for keyword)))
|
||
keywords))))
|
||
|
||
(defun oni-org-generate-tag-faces ()
|
||
"Create faces for all the tags in the current buffer."
|
||
(when-let ((tags (cl-remove-if (lambda (tag) (assoc (car tag) org-tag-faces))
|
||
(org-get-buffer-tags))))
|
||
(append org-tag-faces
|
||
(mapcar (lambda (tag)
|
||
(let ((tag (car tag)))
|
||
(cons tag (oni-org-color-for tag))))
|
||
tags))))
|
||
|
||
(defun oni-org-set-todo-keyword-faces ()
|
||
"Set ‘org-todo-keyword-faces’ to all different colors."
|
||
(setq org-todo-keyword-faces (oni-org-generate-todo-keyword-faces)))
|
||
|
||
(defun oni-org-set-tag-faces ()
|
||
"Set ‘org-tag-faces’ to all different colors."
|
||
(setq org-tag-faces (oni-org-generate-tag-faces))
|
||
(org-set-tag-faces 'org-tag-faces org-tag-faces))
|
||
|
||
;;;###autoload(autoload 'oni-hydra-org/body "oni-org")
|
||
(defhydra oni-hydra-org (:color teal :hint nil)
|
||
"
|
||
^Tasks^ ^Buffer^ ^Capture^
|
||
^^---------------------------------------------------------------------
|
||
_a_: Show Agenda _b_: Switch to org buffer _t_: Note
|
||
_c_: Capture new heading _s_: Save all org buffers _A_: Appointment
|
||
_l_: Store link ^^ _j_: Journal entry
|
||
"
|
||
("l" org-store-link)
|
||
("a" org-agenda)
|
||
("c" org-capture)
|
||
("b" org-switchb)
|
||
("s" org-save-all-org-buffers)
|
||
("t" (org-capture nil "t"))
|
||
("A" (org-capture nil "a"))
|
||
("j" (org-capture nil "j")))
|
||
|
||
(setq org-default-notes-file
|
||
(oni-org-expand-to-home "documents/gtd/inbox.org"))
|
||
|
||
(setq org-agenda-skip-function-global #'oni-org-skip-tasks)
|
||
(setq org-agenda-todo-ignore-scheduled 'future)
|
||
(setq org-catch-invisible-edits 'error)
|
||
(setq org-clock-in-switch-to-state #'oni-org-maybe-change-todo-state)
|
||
(setq org-fontify-whole-heading-line t)
|
||
(setq org-habit-graph-column 60)
|
||
(setq org-hide-emphasis-markers t)
|
||
(setq org-log-into-drawer t)
|
||
(setq org-return-follows-link t)
|
||
(setq org-return-follows-link t)
|
||
(setq org-src-fontify-natively t)
|
||
(setq org-use-fast-todo-selection t)
|
||
|
||
;;; Set the maximum indentation level for description lists to 5 (which is the
|
||
;;; seemingly hardcoded value of the indentation it gets when it goes over
|
||
;;; ‘org-list-description-max-indent’) so that I don’t get dangling descriptions
|
||
;;; when my term is 19 characters long.
|
||
(setq org-list-description-max-indent 5)
|
||
|
||
(setq org-agenda-custom-commands
|
||
'(("c" "Today's (Current) tasks" tags "SCHEDULED=\"<today>\"")
|
||
("t" "Todo" tags-todo "-work-shopping")
|
||
("w" . "Work topics")
|
||
("wo" "Overview" ((tags-todo "+work-remy-mia")
|
||
(tags-todo "+work+idea+mia")
|
||
(tags-todo "+work+idea+remy")))
|
||
("wt" "Word todo" tags-todo "+work-remy-mia")
|
||
("wm" "Topics for Mia" tags-todo "+work+idea+mia")
|
||
("wr" "Topics for Remy" tags-todo "+work+idea+remy")
|
||
("s" . "Shopping")
|
||
("so" "Overview" ((tags-todo "+shopping+home")
|
||
(tags-todo "+shopping+candice")))
|
||
("sh" "Shopping for home" tags-todo "+shopping+home")
|
||
("sc" "Shopping for Candice’s" tags-todo "+shopping+candice")))
|
||
|
||
(setq org-agenda-files
|
||
(mapcar #'oni-org-expand-to-home
|
||
'("documents/gtd/todo.org")))
|
||
|
||
(setq org-refile-targets
|
||
(mapcar (lambda (pair)
|
||
(cons (oni-org-expand-to-home (car pair))
|
||
(cdr pair)))
|
||
'(("documents/gtd/todo.org" :maxlevel . 1)
|
||
("documents/gtd/projects.org" :level . 2)
|
||
("documents/gtd/someday.org" :maxlevel . 1)
|
||
("documents/gtd/music.org" :maxlevel . 1)
|
||
("documents/gtd/books.org" :maxlevel . 1)
|
||
("documents/gtd/bookmarks.org" :maxlevel . 2))))
|
||
|
||
(setq org-capture-templates
|
||
`(("t" "Note" entry
|
||
(file ,(oni-org-expand-to-home "documents/gtd/inbox.org"))
|
||
"* TODO %i%?\n :PROPERTIES:\n :CREATED: %U\n :END:")
|
||
("a" "Appointment" entry
|
||
(file+headline ,(oni-org-expand-to-home "documents/gtd/todo.org")
|
||
"Appointments")
|
||
"* TODO %i%?\n %U")
|
||
("j" "Journal entry" entry
|
||
(file+olp+datetree
|
||
,(oni-org-expand-to-home "documents/gtd/journal.org"))
|
||
"* %<%H:%M:%S>\n %?")
|
||
("c" "Add to currently clocked item")
|
||
("ca" "Note" plain
|
||
(clock)
|
||
" %U\n %?" :empty-lines 1)
|
||
("ci" "Item to current clocked task" item
|
||
(clock)
|
||
" %i%?" :empty-lines 1)
|
||
("cc" "Marked code example with notes" plain
|
||
(clock)
|
||
" %U
|
||
- File: [[file:%F::%(number-to-string (with-current-buffer (get-buffer \"%f\") (line-number-at-pos (region-beginning))))][%f]]
|
||
|
||
%?
|
||
|
||
#+BEGIN_SRC %(string-remove-suffix \"-mode\" (symbol-name (with-current-buffer (get-buffer \"%f\") major-mode)))
|
||
%i
|
||
#+END_SRC"
|
||
:empty-lines 1)
|
||
("cC" "Marked code example" plain
|
||
(clock)
|
||
" #+BEGIN_EXAMPLE\n %i\n #+END_EXAMPLE"
|
||
:immediate-finish t :empty-lines 1)
|
||
("ck" "Kill-ring contents" plain
|
||
(clock)
|
||
" %c" :immediate-finish t :empty-lines 1)))
|
||
|
||
(setq org-todo-keywords
|
||
'((sequence "TODO(t)" "BLOCKED(b@)" "IN-PROGRESS(p)"
|
||
"|" "DONE(d!)" "CANCELLED(c@)")))
|
||
|
||
(setf (alist-get 'file org-link-frame-setup) 'find-file)
|
||
|
||
(add-to-list 'org-modules 'org-habit)
|
||
(add-to-list 'org-modules 'org-tempo)
|
||
|
||
(add-to-list 'org-babel-load-languages '(java . t))
|
||
|
||
(add-hook 'org-mode-hook 'auto-fill-mode)
|
||
(add-hook 'org-mode-hook 'flyspell-mode)
|
||
(add-hook 'org-mode-hook #'oni-org-set-todo-keyword-faces)
|
||
(add-hook 'org-mode-hook #'oni-org-set-tag-faces)
|
||
|
||
(org-edna-mode)
|
||
|
||
(unless (eq system-type 'windows-nt)
|
||
(require 'org-bullets)
|
||
(add-hook 'org-mode-hook 'org-bullets-mode)
|
||
(add-hook 'org-mode-hook #'oni-org-setup-prettify-symbols-mode))
|
||
|
||
;;;###autoload
|
||
(global-set-key (kbd "C-c o") 'oni-hydra-org/body)
|
||
|
||
;;;###autoload
|
||
(global-set-key (kbd "C-<home>") #'oni-org-open-index)
|
||
|
||
;;;###autoload
|
||
(with-eval-after-load 'org
|
||
(with-eval-after-load 'yasnippet
|
||
(oni-org-snippets-initialize)))
|
||
|
||
;;;###autoload(with-eval-after-load 'org (require 'oni-org))
|
||
|
||
(provide 'oni-org)
|
||
;;; oni-org.el ends here
|