104 lines
3.7 KiB
EmacsLisp
104 lines
3.7 KiB
EmacsLisp
;;; oni-csharp.el --- C# Configuration -*- lexical-binding: t; -*-
|
||
|
||
;; Copyright (C) 2019 Tom Willemse
|
||
|
||
;; Author: Tom Willemse <tom@ryuslash.org>
|
||
;; Keywords: local
|
||
;; Version: 2020.0205.224224
|
||
;; Package-Requires: (csharp-mode omnisharp oni-company oni-flycheck)
|
||
|
||
;; This program is free software; you can redistribute it and/or modify
|
||
;; it under the terms of the GNU General Public License as published by
|
||
;; the Free Software Foundation, either version 3 of the License, or
|
||
;; (at your option) any later version.
|
||
|
||
;; This program is distributed in the hope that it will be useful,
|
||
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;; GNU General Public License for more details.
|
||
|
||
;; You should have received a copy of the GNU General Public License
|
||
;; along with this program. If not, see <https://www.gnu.org/licenses/>.
|
||
|
||
;;; Commentary:
|
||
|
||
;; My C# configuration. This configuration enables ‘rainbow-delimiters-mode’.
|
||
|
||
;;; Code:
|
||
|
||
(defvar oni-csharp--projects (make-hash-table :test 'equal))
|
||
|
||
(defun oni-csharp-collect-project-names ()
|
||
"Go through the current buffer and collect all the project names."
|
||
(interactive)
|
||
(clrhash oni-csharp--projects)
|
||
(save-excursion
|
||
(goto-char (point-min))
|
||
(while (re-search-forward
|
||
(rx bol
|
||
"Project(\"{"
|
||
(group (minimal-match (1+ (or alphanumeric "-"))))
|
||
"}\") = \""
|
||
(group (minimal-match (1+ any)))
|
||
"\", \""
|
||
(minimal-match (1+ any))
|
||
"\", \"{"
|
||
(group (minimal-match (1+ any)))
|
||
"}\""
|
||
eol)
|
||
nil
|
||
:noerror)
|
||
(puthash (match-string-no-properties 3)
|
||
(match-string-no-properties 2)
|
||
oni-csharp--projects))))
|
||
|
||
(defun oni-csharp-display-project-names ()
|
||
"Display the project names in the current buffer."
|
||
(interactive)
|
||
(save-excursion
|
||
(goto-char (point-min))
|
||
(remove-overlays (point-min) (point-max) 'oni-csharp--overlayp t)
|
||
(while (re-search-forward
|
||
(rx bol
|
||
(zero-or-more whitespace)
|
||
"{"
|
||
(group (minimal-match (one-or-more (or alphanumeric "-"))))
|
||
"} = {"
|
||
(group (minimal-match (one-or-more (or alphanumeric "-"))))
|
||
"}"
|
||
eol)
|
||
nil
|
||
:noerror)
|
||
(let ((current-overlay (make-overlay (line-beginning-position) (line-end-position))))
|
||
(overlay-put current-overlay 'after-string
|
||
(propertize (format " => %s" (gethash (match-string 1) oni-csharp--projects))
|
||
'face '(:foreground "#808080")))
|
||
(overlay-put current-overlay 'oni-csharp--overlayp t)
|
||
(overlay-put current-overlay 'evaporate t)))))
|
||
|
||
(defun oni-csharp--auto-fill-mode ()
|
||
"Enable ‘auto-fill-mode’ only for comments."
|
||
(setq-local comment-auto-fill-only-comments t)
|
||
(auto-fill-mode))
|
||
|
||
(with-eval-after-load 'company
|
||
(add-to-list 'company-backends 'company-omnisharp))
|
||
|
||
(add-hook 'csharp-mode-hook 'company-mode)
|
||
(add-hook 'csharp-mode-hook 'electric-indent-local-mode)
|
||
(add-hook 'csharp-mode-hook 'electric-pair-local-mode)
|
||
(add-hook 'csharp-mode-hook 'flycheck-mode)
|
||
(add-hook 'csharp-mode-hook 'omnisharp-mode)
|
||
(add-hook 'csharp-mode-hook 'oni-csharp--auto-fill-mode)
|
||
(add-hook 'csharp-mode-hook 'rainbow-delimiters-mode)
|
||
|
||
;;;###autoload
|
||
(add-to-list 'auto-mode-alist '("\\.xaml\\'" . nxml-mode))
|
||
|
||
;;;###autoload
|
||
(add-to-list 'auto-mode-alist '("\\.csproj\\'" . nxml-mode))
|
||
|
||
;;;###autoload(with-eval-after-load 'csharp-mode (require 'oni-csharp))
|
||
|
||
(provide 'oni-csharp)
|
||
;;; oni-csharp.el ends here
|