emacs-config/oni-core.el

;;; oni-core.el --- Core Emacs configuration         -*- lexical-binding: t; -*-

;; Copyright (C) 2019  Tom Willemse

;; Author: Tom Willemse <tom@ryuslash.org>
;; Keywords: local
;; Version: 2023.0524.235720
;; Package-Requires: (oni-data-dir oni-embrace oni-hydra expand-region multiple-cursors gcmh diminish ws-butler which-key insert-char-preview mixed-pitch ace-window vertico marginalia orderless consult embark docstr mini-frame)

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; Core Emacs configuration, doesn't need any requires from within
;; Emacs. These settings don't seem to go anywhere else. Add the following to
;; your init file in case you want to use this configuration:
;;
;;     (require 'oni-core)

;;; Code:

(require 'auth-source)
(require 'diminish)
(require 'gcmh)
(require 'generic-x)
(require 'hydra)
(require 'package)
(require 'recentf)
(require 'which-key)
(require 'ws-butler)

(require 'oni-data-dir)

(defconst oni-core--auto-save-directory (oni-data-dir-locate "auto-save-files/")
  "Directory where auto-saves go.")

(defalias 'yes-or-no-p 'y-or-n-p)

(defvar oni-core--recentf-idle-timer nil
  "Internal variable keeping track of a timer started for ‘recentf-save-list’.")

(defun oni-core--switch-newline-keys ()
  "Switch the ‘C-j’ and ‘RET’ keys in the local buffer."
  (if electric-indent-mode
      (progn
        (local-set-key (kbd "C-j") 'newline)
        (local-set-key (kbd "RET") 'electric-newline-and-maybe-indent))
    (local-unset-key (kbd "C-j"))
    (local-unset-key (kbd "RET"))))

(defun oni-core--ensure-autosave-directory-exists ()
  "Create the autosave directory if doesn't exist."
  (mkdir oni-core--auto-save-directory t))

(defun oni-core-move-beginning-of-dwim ()
  "Move to beginning of line either after indentation or before."
  (interactive)
  (let ((start (point)))
    (back-to-indentation)
    (unless (/= start (point))
      (move-beginning-of-line 1))))

(defun oni-core-move-end-of-dwim ()
  "Move to end of line, either before any comments or after."
  (interactive)
  (let ((start (point))
        (eolpos (line-end-position)))
    (beginning-of-line)
    (if (and comment-start
             (not (looking-at (regexp-quote comment-start)))
             (comment-search-forward eolpos t))
        (condition-case _
            (progn
              (search-backward-regexp (concat "[^ \t" comment-start "]"))
              (forward-char)
              (when (or (bolp)
                        (= start (point)))
                (end-of-line)))
          (search-failed (end-of-line)))
      (end-of-line))))

;;; From Bastien Guerry’s Emacs configuraiton:
;;; https://github.com/bzg/dotemacs/blob/master/emacs.org
(defun oni-core-unfill-paragraph ()
  "Make a multi-line paragraph into a single line of text."
  (interactive)
  (let ((fill-column (point-max)))
    (fill-paragraph nil)))

(defun oni-core-recentf-save-list-silently ()
  "Call ‘recentf-save-list’ but without showing a message about it."
  (let ((inhibit-message t))
    (recentf-save-list)))

(defhydra oni-sort-and-align-hydra (:color teal :hint nil)
  "
     ^Sort^
^^--------------
_l_: Lines
_p_: Paragraph
_s_: String list"
  ("l" sort-lines)
  ("p" (save-excursion
         (sort-lines
          nil
          (progn (start-of-paragraph-text) (point))
          (progn (end-of-paragraph-text) (point)))))
  ("s" (sort-regexp-fields
        nil
        (rx "\"" (one-or-more (not "\"")) "\"")
        (rx (one-or-more (not "\"")))
        (region-beginning)
        (region-end))))

(add-to-list 'auto-save-file-name-transforms
	         `(".*" ,oni-core--auto-save-directory t)
	         :append)

(setq backup-directory-alist
      `((".*" . ,(oni-data-dir-locate "backup-files"))))

(setq auto-save-list-file-prefix
      (oni-data-dir-locate "auto-save-list/.saves-"))

(setq abbrev-file-name (oni-data-dir-locate "abbrev_defs"))

(setq recentf-save-file (oni-data-dir-locate "recentf"))

;;; Get rid of the default help tooltip on the mode-line.
(setq mode-line-default-help-echo nil)

(setq user-full-name "Tom Willemse"
      user-mail-address "tom@ryuslash.org")

(setq delete-old-versions t)
(setq kept-new-versions 20)
(setq kept-old-versions 20)
(setq vc-make-backup-files t)
(setq version-control t)
(setq require-final-newline t)
(setq sentence-end-double-space nil)
(setq inhibit-startup-screen t)
(setq electric-pair-skip-whitespace 'chomp)
(setq fit-window-to-buffer-horizontally t)
;; Discovered through
;; https://github.com/novoid/dot-emacs/blob/23c28944f1991c636ea71ec7d5c3d266e6dbeb8a/config.org#deletes-duplicate-entries-of-the-history-of-the-minibuffer
(setq history-delete-duplicates t)

(let ((tips '("Play more in order to learn more"
              "Learn from similarities, unlearn from differences"
              "Explore, invent, and apply in your environment - safely"
              "See without judging and then act"
              "Give yourself permission to fail; it’s the path to success"
              "Groove your mind for success"
              "Learn to focus"
              "Make thinking time"
              "Use a wiki to manage information and knowledge"
              "Establish rules of engagement to manage interruptions"
              "Send less email, and you’ll receive less email"
              "Choose your own tempo for an email conversation"
              "Mask interrupts to maintain focus"
              "Use multiple monitors to avoid context switching"
              "Optimize your personal workflow to maximize context"
              "Grab the wheel. You can’t steer on autopilot"
              "Can it be simpler?")))
  (setq initial-scratch-message
        (concat initial-scratch-message ";; " (seq-random-elt tips) "\n\n")))

;; Increase the threshold for garbage collection for increased performance.
;; Apparently there are some (lsp-mode for example) packages that generate a lot
;; of garbage.
(setq gc-cons-threshold 100000000)

;;; Remove ~/.authinfo from the auth sources since it’s an unencripted file and
;;; I don’t want to accidentally store anything in there.
(setq auth-sources
      (cons "secrets:Login"
            (remove "~/.netrc"
                    (remove "~/.authinfo" auth-sources))))

(setq read-mail-command 'gnus)

(setq-default indent-tabs-mode nil)
(setq-default tab-width 4)
(setq-default truncate-lines t)
(setq-default fill-column 80)

(add-hook 'Info-mode-hook 'mixed-pitch-mode)
(add-hook 'after-save-hook 'executable-make-buffer-file-executable-if-script-p)
(add-hook 'auto-save-hook #'oni-core--ensure-autosave-directory-exists)
(add-hook 'before-save-hook 'time-stamp)
(add-hook 'electric-indent-local-mode-hook #'oni-core--switch-newline-keys)
(add-hook 'minibuffer-setup-hook 'electric-pair-local-mode)
(add-hook 'prog-mode-hook 'goto-address-prog-mode)

(global-set-key (kbd "C-M-SPC") 'er/expand-region)
(global-set-key (kbd "C-S-b") 'windmove-left)
(global-set-key (kbd "C-S-f") 'windmove-right)
(global-set-key (kbd "C-S-n") 'windmove-down)
(global-set-key (kbd "C-S-p") 'windmove-up)
(global-set-key (kbd "C-c (") '("Embrace Commander" . embrace-commander))
(global-set-key (kbd "C-c q") '("Unfill Paragraph" . oni-core-unfill-paragraph))
(global-set-key (kbd "C-c s") '("Sort and Align Commands" . oni-sort-and-align-hydra/body))
(global-set-key (kbd "C-c l") 'imenu)
(global-set-key (kbd "C-x C-b") '("List Buffers" . ibuffer-jump))
(global-set-key (kbd "C-x M-f") 'ffap)
(global-set-key (kbd "M-+") 'mc/mark-next-like-this)
(global-set-key [remap insert-char] 'insert-char-preview)
(global-set-key [remap move-beginning-of-line] #'oni-core-move-beginning-of-dwim)
(global-set-key [remap move-end-of-line] #'oni-core-move-end-of-dwim)
(global-set-key [remap upcase-word] #'upcase-dwim)
(global-set-key [remap downcase-word] #'downcase-dwim)
(global-set-key [remap capitalize-word] #'capitalize-dwim)

(global-set-key (kbd "C-<left>") 'winner-undo)
(global-set-key (kbd "C-<right>") 'winner-redo)

(global-set-key (kbd "M-o") 'ace-window)
(global-unset-key (kbd "C-x o"))

(unless oni-core--recentf-idle-timer
  (setq oni-core--recentf-idle-timer
        (run-with-idle-timer 10 t #'oni-core-recentf-save-list-silently)))

(with-eval-after-load 'gcmh (diminish 'gcmh-mode))
(with-eval-after-load 'ws-butler (diminish 'ws-butler-mode))
(with-eval-after-load 'which-key (diminish 'which-key-mode))

(add-to-list 'display-buffer-alist
             `(,(rx string-start
                    "*" (any ?h ?H) "elp")
               display-buffer-in-side-window
               (side . bottom)
               (slot . 0)
               (window-height . 0.33)))

(when (eql system-type 'windows-nt)
  (add-to-list 'load-path (locate-user-emacs-file "vendor/p4-vc"))
  (add-to-list 'exec-path "c:/Program Files/Git/bin")
  (add-to-list 'exec-path "C:/Program Files/Git/usr/bin")
  (add-to-list 'exec-path "c:/cygwin64/bin" t)

  (setq delete-by-moving-to-trash t)

  (setq-default buffer-file-coding-system 'utf-8-unix))

;; Set up autoloads for all of my configuration files so that when they get
;; installed they get loaded automatically, but don’t require them to be
;; installed.

(with-eval-after-load 'ahk-mode (require 'oni-autohotkey))
(with-eval-after-load 'alert (require 'oni-alert))
(with-eval-after-load 'bat-mode (require 'oni-bat))
(with-eval-after-load 'bats (require 'oni-bats))
(with-eval-after-load 'bookmark (require 'oni-bookmark))
(with-eval-after-load 'browse-url (require 'oni-browse-url))
(with-eval-after-load 'cc-mode (require 'oni-c nil t))
(with-eval-after-load 'cc-mode (require 'oni-cpp nil t))
(with-eval-after-load 'cc-mode (require 'oni-java nil t))
(with-eval-after-load 'cider (require 'oni-clojure))
(with-eval-after-load 'circe (require 'oni-circe))
(with-eval-after-load 'clojure-mode (require 'oni-clojure))
(with-eval-after-load 'cmake-mode (require 'oni-cmake))
(with-eval-after-load 'company (require 'oni-company))
(with-eval-after-load 'compile (require 'oni-compilation))
(with-eval-after-load 'conf-mode (require 'oni-conf))
(with-eval-after-load 'counsel (require 'oni-counsel))
(with-eval-after-load 'csharp-mode (require 'oni-csharp))
(with-eval-after-load 'css-mode (require 'oni-css))
(with-eval-after-load 'diff-hl (require 'oni-diff-hl))
(with-eval-after-load 'dired (require 'oni-dired))
(with-eval-after-load 'ediff (require 'oni-ediff))
(with-eval-after-load 'elfeed (require 'oni-elfeed))
(with-eval-after-load 'elisp-mode (require 'oni-elisp))
(with-eval-after-load 'elm-mode (require 'oni-elm))
(with-eval-after-load 'embrace (require 'oni-embrace))
(with-eval-after-load 'emms (require 'oni-emms))
(with-eval-after-load 'eshell (require 'oni-eshell))
(with-eval-after-load 'fish-mode (require 'oni-fish))
(with-eval-after-load 'flycheck (require 'oni-flycheck))
(with-eval-after-load 'git-commit (require 'oni-git-commit))
(with-eval-after-load 'gnus (require 'oni-gnus))
(with-eval-after-load 'grep (require 'oni-grep))
(with-eval-after-load 'groovy-mode (require 'oni-groovy))
(with-eval-after-load 'haskell-mode (require 'oni-haskell))
(with-eval-after-load 'highlight-indent-guides (require 'oni-highlight-indent-guides))
(with-eval-after-load 'hydra (require 'oni-hydra))
(with-eval-after-load 'ielm (require 'oni-elisp))
;; (with-eval-after-load 'ivy (require 'oni-ivy))
(with-eval-after-load 'jabber (require 'oni-jabber))
(with-eval-after-load 'js2-mode (require 'oni-js))
(with-eval-after-load 'json-mode (require 'oni-json))
(with-eval-after-load 'lisp-mode (require 'oni-common-lisp))
(with-eval-after-load 'log-edit (require 'oni-log-edit))
(with-eval-after-load 'lsp (require 'oni-lsp))
(with-eval-after-load 'lua-mode (require 'oni-lua))
(with-eval-after-load 'lui (require 'oni-lui))
(with-eval-after-load 'magit (require 'oni-magit))
(with-eval-after-load 'make-mode (require 'oni-makefile))
(with-eval-after-load 'notmuch (require 'oni-notmuch))
(with-eval-after-load 'nov (require 'oni-epub))
(with-eval-after-load 'org (require 'oni-org))
(with-eval-after-load 'org-roam (require 'oni-org-roam))
(with-eval-after-load 'package (require 'oni-package))
(with-eval-after-load 'package-x (require 'oni-package))
(with-eval-after-load 'paredit (require 'oni-paredit))
(with-eval-after-load 'php-mode (require 'oni-php))
(with-eval-after-load 'prescient (require 'oni-prescient))
(with-eval-after-load 'projectile (require 'oni-projectile))
(with-eval-after-load 'python (require 'oni-python))
(with-eval-after-load 'ruby-mode (require 'oni-ruby))
(with-eval-after-load 'rust-mode (require 'oni-rust))
(with-eval-after-load 'scheme (require 'oni-scheme))
(with-eval-after-load 'sgml-mode (require 'oni-html))
(with-eval-after-load 'sh (require 'oni-sh))
(with-eval-after-load 'shr (require 'oni-shr))
(with-eval-after-load 'smartparens (require 'oni-smartparens))
(with-eval-after-load 'sort (require 'oni-sort))
(with-eval-after-load 'tramp (require 'oni-tramp))
(with-eval-after-load 'vc (require 'oni-vc))
(with-eval-after-load 'vterm (require 'oni-vterm))
(with-eval-after-load 'web-mode (require 'oni-web))
(with-eval-after-load 'yaml-mode (require 'oni-yaml))

(with-eval-after-load 'yasnippet
  (require 'oni-yasnippet)
  (when (and (package-installed-p 'oni-yasnippet)
             (not yas-global-mode))
    (yas-global-mode)))

(eval-when-compile
  (require 'calendar))

(with-eval-after-load 'calendar
  ;; I’m used to working with Monday as the starting day.
  (setq calendar-week-start-day 1
        calendar-date-style 'iso))

(eval-when-compile (require 'solar))
(with-eval-after-load 'solar
  (setq calendar-latitude 49.2127205
        calendar-longitude -122.9267927))

(defun oni-core-in-word-p ()
  "Check whether the character just typed was part of a word."
  (save-excursion
    (backward-char)
    (looking-back (rx word) (1- (point)))))

(defun oni-core-ace-window-select-other-window ()
  "Use ‘ace-window’ to select which window is considered “other”."
  (interactive)
  (setq other-window-scroll-buffer (ace-select-window)))

(with-eval-after-load 'electric
  (add-hook 'electric-quote-inhibit-functions #'oni-core-in-word-p))

(eval-when-compile (require 'ispell))
(with-eval-after-load 'ispell
  (setq ispell-program-name "hunspell"
        ispell-really-hunspell t))

;; Enable any modes that I want to have turned on right away.

(electric-indent-mode -1)
(winner-mode)
(recentf-mode)
(gcmh-mode)
(ws-butler-global-mode)
(which-key-mode)
(auto-insert-mode)
(global-diff-hl-mode)
;;; Remember minibuffer history across sessions.
(savehist-mode)
;;; Remember the place I left at in files when closing them.
(save-place-mode)

;;; Vertico

(vertico-mode)

;;; Marginalia

(define-key minibuffer-local-map (kbd "M-A") 'marginalia-cycle)

(marginalia-mode)

;;; Orderless

(setq completion-styles '(basic partial-completion orderless))

;;; Consult

(global-set-key (kbd "C-c w d") '("Delete a window" . ace-delete-window))
(global-set-key (kbd "C-c w k") '("Keep a single window" . ace-delete-other-windows))
(global-set-key (kbd "C-c w o") '("Select other window" . oni-core-ace-window-select-other-window))
(global-set-key (kbd "M-g M") '("Jump to a mark anywhere" . consult-global-mark))
(global-set-key (kbd "M-g m") '("Jump to a mark" . consult-mark))
(global-set-key [remap bookmark-jump] 'consult-bookmark)
(global-set-key [remap goto-line] 'consult-goto-line)
(global-set-key [remap imenu] 'consult-imenu)
(global-set-key [remap project-switch-to-buffer] 'consult-project-buffer)
(global-set-key [remap projectile-switch-to-buffer] 'consult-project-buffer)
(global-set-key [remap switch-to-buffer] 'consult-buffer)
(global-set-key [remap yank-pop] 'consult-yank-pop)

(global-set-key (kbd "M-0") #'delete-window)
(global-set-key (kbd "C-x 0") (lambda () (interactive) (error "Use M-0 instead")))
(global-set-key (kbd "M-1") #'delete-other-windows)
(global-set-key (kbd "C-x 1") (lambda () (interactive) (error "Use M-1 instead")))
(global-set-key (kbd "M-2") #'split-window-below)
(global-set-key (kbd "C-x 2") (lambda () (interactive) (error "Use M-2 instead")))
(global-set-key (kbd "M-3") #'split-window-right)
(global-set-key (kbd "C-x 3") (lambda () (interactive) (error "Use M-3 instead")))
(global-set-key (kbd "M-4") #'ctl-x-4-prefix)
(global-set-key (kbd "C-x 4") (lambda () (interactive) (error "Use M-4 instead")))
(global-set-key (kbd "M-5") #'ctl-x-5-prefix)
(global-set-key (kbd "C-x 5") (lambda () (interactive) (error "Use M-5 instead")))
(global-set-key (kbd "M-6") #'2C-command)
(global-set-key (kbd "C-x 6") (lambda () (interactive) (error "Use M-6 instead")))
(global-set-key (kbd "M-8") (keymap-lookup global-map "C-x 8"))
(global-set-key (kbd "C-x 8") (lambda () (interactive) (error "Use M-8 instead")))

(defun oni-core-related-files ()
  "Return a list of files related to the current buffer."
  (let* ((jumpers related-files-jumpers)
         (current-place (buffer-file-name)))
    (cond ((not jumpers)
           (user-error "No jumpers.  Consider configuring `related-files-jumpers'"))
          ((not current-place)
           (user-error "Related-Files only works from file-based buffers"))
          (t
           (related-files--collect-existing-places jumpers (list current-place))))))

(defvar oni-core-related-places-source
  '(:name "Related File"
    :category file
    :items oni-core-related-files
    :enabled buffer-file-name
    :action find-file))

(defun oni-core-remove-consult-buffer-preview ()
  (consult-customize consult-buffer :preview-key nil))

(with-eval-after-load 'consult
  (with-eval-after-load 'related-files
    (add-to-list 'consult-buffer-sources 'oni-core-related-places-source))

  (oni-core-remove-consult-buffer-preview))

;;; Embark

(global-set-key (kbd "C-.") 'embark-act)
(global-set-key (kbd "C-;") 'embark-dwim)
(global-set-key [remap describe-bindings] 'embark-bindings)

(defun oni-core-fit-window-to-buffer (window)
  (fit-window-to-buffer window)
  (with-selected-window window
    (enlarge-window-horizontally 1)))

(add-to-list 'display-buffer-alist
             `(,(rx string-start " *Embark Actions*")
               display-buffer-in-side-window
               (window-parameter (mode-line-format . none))
               (side . right)
               (slot . 0)
               (window-width . oni-core-fit-window-to-buffer)))

;;; Extra debugging

;;; From https://gist.github.com/jdtsmith/1fbcacfe677d74bbe510aec80ac0050c
(defun oni-core-reraise-error (func &rest args)
  "Call function FUNC with ARGS and re-raise any error which occurs.
Useful for debugging post-command hooks and filter functions,
which normally have their errors suppressed."
  (condition-case err
      (apply func args)
    ((debug error) (signal (car err) (cdr err)))))

(defun toggle-debug-on-hidden-errors (func)
  "Toggle hidden error debugging for function FUNC."
  (interactive "a")
  (cond
   ((advice-member-p #'oni-core-reraise-error func)
    (advice-remove func #'oni-core-reraise-error)
    (message "Debug on hidden errors disabled for %s" func))
   (t
    (advice-add func :around #'oni-core-reraise-error)
    (message "Debug on hidden errors enabled for %s" func))))

;;; Native Compilation

(setq native-comp-async-report-warnings-errors 'silent)

;;; Mini frame

(require 'mini-frame)

(setq mini-frame-show-parameters
      '((top . 10)
        (width . 0.7)
        (left . 0.5)))

(mini-frame-mode)

(provide 'oni-core)
;;; oni-core.el ends here