emacs-config/oni-eshell.el

;;; oni-eshell.el --- Eshell configuration           -*- lexical-binding: t; -*-

;; Copyright (C) 2019  Tom Willemse

;; Author: Tom Willemse <tom@ryuslash.org>
;; Keywords: local
;; Version: 2019.0904.210523
;; Package-Requires: (eshell-fringe-status esh-autosuggest)

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; Eshell configuration.

;;; Code:

(require 'eshell)
(require 'em-prompt)
(require 'esh-autosuggest)

(defun oni-eshell--C-d ()
  "Call `delete-char' or close the buffer if it fails."
  (interactive)
  (condition-case err
      (call-interactively #'delete-char)
    (error (if (and (eq (car err) 'end-of-buffer)
                    (looking-back eshell-prompt-regexp nil))
               (kill-buffer)
             (signal (car err) (cdr err))))))

(defun oni-eshell--enable-truncating-buffers ()
  "Add `eshell-truncate-buffer' to `eshell-output-filter-functions'."
  (add-to-list 'eshell-output-filter-functions 'eshell-truncate-buffer))

(defun oni-eshell--set-eshell-C-d ()
  "Set `C-d' to quit eshell if used at end of prompt."
  (define-key eshell-mode-map (kbd "C-d") #'oni-eshell--C-d))

(add-hook 'eshell-first-time-mode-hook #'oni-eshell--set-eshell-C-d)
(add-hook 'eshell-load-hook #'oni-eshell--enable-truncating-buffers)
(add-hook 'eshell-mode-hook 'esh-autosuggest-mode)
(add-hook 'eshell-mode-hook 'goto-address-mode)

(when (display-graphic-p)
  (add-hook 'eshell-mode-hook 'eshell-fringe-status-mode))

;;;###autoload(with-eval-after-load 'eshell (require 'oni-eshell))

(provide 'oni-eshell)
;;; oni-eshell.el ends here