emacs-config/oni-cmake.el

;;; oni-cmake.el --- CMake configuration             -*- lexical-binding: t; -*-

;; Copyright (C) 2019  Tom Willemse

;; Author: Tom Willemse <tom@ryuslash.org>
;; Keywords: local
;; Version: 2022.0203.215032
;; Package-Requires: (cmake-mode oni-company oni-flycheck oni-lsp cmake-font-lock eldoc-cmake)

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; CMake configuration.

;;; Code:

(require 'cmake-mode)
(require 'compile)
(require 'flycheck)

(defun oni-cmake--auto-fill-mode ()
  "Enable ‘auto-fill-mode’ only for comments."
  (setq-local comment-auto-fill-only-comments t)
  (auto-fill-mode))

(defun oni-cmake-narrow-to-defun (&optional _include-comments)
  "Narrow the current buffer the the function around point.
_INCLUDE-COMMENTS is currently ignored."
  (interactive)
  (save-excursion
    (let ((end (progn (cmake-end-of-defun)
                      (point)))
          (beginning (progn (cmake-beginning-of-defun)
                            (point))))
      (narrow-to-region beginning end))))

(define-key cmake-mode-map (kbd "C-x n d") #'oni-cmake-narrow-to-defun)

(add-hook 'cmake-mode-hook 'cmake-font-lock-activate)
(add-hook 'cmake-mode-hook 'company-mode)
(add-hook 'cmake-mode-hook 'display-fill-column-indicator-mode)
(add-hook 'cmake-mode-hook 'eldoc-cmake-enable)
(add-hook 'cmake-mode-hook 'electric-indent-local-mode)
(add-hook 'cmake-mode-hook 'electric-pair-local-mode)
(add-hook 'cmake-mode-hook 'lsp)
(add-hook 'cmake-mode-hook 'oni-cmake--auto-fill-mode)
(add-hook 'cmake-mode-hook 'rainbow-delimiters-mode)

(add-to-list 'compilation-error-regexp-alist
             `(,(rx bol
                    "CMake Warning (dev) at "
                    (group (minimal-match (1+ any)))
                    ":"
                    (group (minimal-match (1+ digit)))
                    " (" (1+ any) "):"
                    eol)
               1 2 nil 1 1))

(flycheck-define-checker cmake-cmakelint
  "A CMake checker using cmakelint.

See URL `https://github.com/richq/cmake-lint'"
  :command ("cmakelint" source)
  :error-patterns ((error line-start (file-name) ":" line ": " (message) line-end))
  :modes cmake-mode)

;;;###autoload
(with-eval-after-load 'grep
  (add-to-list 'grep-files-aliases
               '("cmake" . "CMakeLists.txt *.cmake CMakePresets.json CMakeUserPresets.json")))

(provide 'oni-cmake)
;;; oni-cmake.el ends here