summaryrefslogtreecommitdiffstats
path: root/emacs/site-lisp
diff options
context:
space:
mode:
Diffstat (limited to 'emacs/site-lisp')
-rw-r--r--emacs/site-lisp/Makefile7
-rw-r--r--emacs/site-lisp/dzen.el86
-rw-r--r--emacs/site-lisp/eltuki.el232
-rw-r--r--emacs/site-lisp/ext.el56
-rw-r--r--emacs/site-lisp/metalexpress.el80
-rw-r--r--emacs/site-lisp/mu4e-init.el54
-rw-r--r--emacs/site-lisp/newsticker-init.el6
-rw-r--r--emacs/site-lisp/oni.el574
-rw-r--r--emacs/site-lisp/org-init.el164
-rw-r--r--emacs/site-lisp/quick-edit-mode.el74
-rw-r--r--emacs/site-lisp/wm-init.el3
11 files changed, 1336 insertions, 0 deletions
diff --git a/emacs/site-lisp/Makefile b/emacs/site-lisp/Makefile
new file mode 100644
index 0000000..bbccbb7
--- /dev/null
+++ b/emacs/site-lisp/Makefile
@@ -0,0 +1,7 @@
+DESTDIR:=$(DESTDIR)/site-lisp
+objects=dzen.elc dzen.el eltuki.elc eltuki.el ext.elc ext.el \
+ metalexpress.elc metalexpress.el mu4e-init.elc mu4e-init.el \
+ newsticker-init.elc newsticker-init.el oni.elc oni.el org-init.elc \
+ org-init.el quick-edit-mode.elc quick-edit-mode.el
+
+include ../../dotfiles.mk
diff --git a/emacs/site-lisp/dzen.el b/emacs/site-lisp/dzen.el
new file mode 100644
index 0000000..6cc3eae
--- /dev/null
+++ b/emacs/site-lisp/dzen.el
@@ -0,0 +1,86 @@
+;;; dzen.el --- Control DZEN2 from emacs
+
+;; Copyright (C) 2012 Tom Willemsen
+
+;; Author: Tom Willemsen <slash@drd>
+;; Keywords: convenience
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program. If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;;
+
+;;; Code:
+
+(require 'newst-backend)
+(require 'sawfish)
+
+(defvar dzen-process nil
+ "Dzen2's process.")
+
+(defvar dzen-timer nil
+ "Timer used to update the dzen line.")
+
+(defun get-mail-count (account)
+ (length (directory-files (concat "/home/slash/documents/mail/"
+ account "/inbox/new") nil "^[^.]")))
+
+(defun dzen-update ()
+ (let ((strl "")
+ (strc (if (boundp 'metal-express-radio-currently-playing)
+ metal-express-radio-currently-playing
+ ""))
+ (strr (format
+ "jabber: %s ryu: %d gm: %d aet: %d 9n: %d rss: %d\n"
+ (oni:current-jabber-status)
+ (get-mail-count "ryuslash.org")
+ (get-mail-count "gmail")
+ (get-mail-count "aethon")
+ (get-mail-count "ninthfloor")
+ (newsticker--stat-num-items-total 'new))))
+ (process-send-string
+ "dzen2" (format "%s^p(_CENTER)^p(-%d)%s^p(_RIGHT)^p(-%d)%s"
+ strl
+ (* (floor (/ (length strc) 2)) 8) strc
+ (+ 8 (* 8 (length strr))) strr))))
+
+(defun dzen-start ()
+ (interactive)
+ (if (or (null dzen-process) (not (process-live-p dzen-process)))
+ (progn
+ (setq dzen-process
+ (start-process "dzen2" "*dzen2*" "dzen2"
+ "-w" "1920"
+ "-fn" "Monaco-10"
+ "-bg" "#222224"
+ "-fg" "#eeeeec"
+ "-y" "1060"))
+ (dzen-update)
+ (setq dzen-timer (run-with-timer 1 1 #'dzen-update)))
+ (message "Dzen2 already running")))
+
+(defun dzen-stop ()
+ (interactive)
+ (if (and dzen-process (process-live-p dzen-process))
+ (progn
+ (when dzen-timer
+ (cancel-timer dzen-timer))
+ (kill-process "dzen2"))
+ (message "Dzen2 is not running"))
+ (setq dzen-process nil
+ dzen-timer nil))
+
+(provide 'dzen)
+;;; dzen.el ends here
diff --git a/emacs/site-lisp/eltuki.el b/emacs/site-lisp/eltuki.el
new file mode 100644
index 0000000..224e9ab
--- /dev/null
+++ b/emacs/site-lisp/eltuki.el
@@ -0,0 +1,232 @@
+;;; eltuki.el --- Tekuti functions
+
+;; Copyright (C) 2012 Tom Willemsen
+
+;; Author: Tom Willemsen <slash@drd>
+;; Keywords: convenience
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program. If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; Tekuti functions.
+
+;;; Code:
+
+(require 'org)
+
+(defgroup eltuki
+ nil
+ "tekuti functions in Emacs."
+ :group 'external)
+
+(defcustom eltuki-blog-dir "~/blog"
+ "Plain blog post directory, not the git repository."
+ :group 'eltuki
+ :type 'string)
+
+(defcustom eltuki-default-status "publish"
+ "Default status to use when status is unknown."
+ :group 'eltuki
+ :type 'string)
+
+(defcustom eltuki-default-comment-status "open"
+ "Default status for comments."
+ :group 'eltuki
+ :type 'string)
+
+(define-skeleton eltuki-post
+ "Create a post template for eltuki."
+ ""
+ "#+TITLE: " (skeleton-read "Title: ") "\n"
+ "#+TIMESTAMP: \n"
+ "#+TAGS: " (skeleton-read "Tags (comma separated): ") "\n"
+ "\n"
+ _)
+
+(defun eltuki-new-post ()
+ (interactive)
+ (switch-to-buffer (get-buffer-create "*eltuki*"))
+ (org-mode)
+ (eltuki-post))
+
+(defun eltuki-get-title ()
+ (save-excursion
+ (goto-char (point-min))
+ (if (re-search-forward "^#\\+TITLE: \\(.*\\)$" nil t)
+ (buffer-substring-no-properties
+ (match-beginning 1) (match-end 1))
+ (error "Post has no title."))))
+
+(defun eltuki-set-title (title)
+ (interactive "MTitle: ")
+ (setq title (concat " " title))
+ (save-excursion
+ (goto-char (point-min))
+ (if (re-search-forward "^#\\+TITLE:\\(.*\\)$" nil t)
+ (replace-match title t t nil 1)
+ (insert "#+TITLE:" title "\n")
+ (unless (= (char-after) ?\n)
+ (insert-char ?\n)))))
+
+(defun eltuki-get-timestamp ()
+ (save-excursion
+ (goto-char (point-min))
+ (if (re-search-forward "^#\\+TIMESTAMP: \\([[:digit:]]+\\)$" nil t)
+ (match-string 1)
+ (format-time-string "%s"))))
+
+(defun eltuki-set-timestamp ()
+ (interactive)
+ (save-excursion
+ (goto-char (point-min))
+ (let ((newtime (format-time-string " %s")))
+ (if (re-search-forward "^#\\+TIMESTAMP:\\(.*\\)$" nil t)
+ (replace-match newtime nil t nil 1)
+ (when (search-forward "\n\n" nil t)
+ (backward-char))
+ (insert "#+TIMESTAMP:" newtime "\n")))))
+
+(defun eltuki-get-tags ()
+ (save-excursion
+ (goto-char (point-min))
+ (when (re-search-forward "^#\\+TAGS: \\(.*\\)$" nil t)
+ (buffer-substring-no-properties
+ (match-beginning 1) (match-end 1)))))
+
+(defun eltuki-set-tags (tags)
+ (interactive "MTags: ")
+ (setq tags (concat " " tags))
+ (save-excursion
+ (goto-char (point-min))
+ (if (re-search-forward "^#\\+TAGS:\\(.*\\)$" nil t)
+ (replace-match tags t t nil 1)
+ (when (search-forward "\n\n" nil t)
+ (backward-char))
+ (insert "#+TAGS:" tags "\n"))))
+
+(defun eltuki-get-status ()
+ (save-excursion
+ (goto-char (point-min))
+ (if (re-search-forward "^#\\+STATUS: \\(draft\\|publish\\)$" nil t)
+ (buffer-substring-no-properties
+ (match-beginning 1) (match-end 1))
+ eltuki-default-status)))
+
+(defun eltuki-toggle-status ()
+ (interactive)
+ (save-excursion
+ (goto-char (point-min))
+ (let ((newstatus (if (string= (eltuki-get-status) "draft")
+ " publish"
+ " draft")))
+ (if (re-search-forward "^#\\+STATUS:\\(.*\\)$" nil t)
+ (replace-match newstatus t t nil 1)
+ (when (search-forward "\n\n" nil t)
+ (backward-char))
+ (insert "#+STATUS:" newstatus "\n")))))
+
+(defun eltuki-get-comment-status ()
+ (save-excursion
+ (goto-char (point-min))
+ (if (re-search-forward
+ "^#\\+COMMENTSTATUS: \\(open\\|closed\\)$" nil t)
+ (buffer-substring-no-properties
+ (match-beginning 1) (match-end 1))
+ eltuki-default-comment-status)))
+
+(defun eltuki-toggle-comment-status ()
+ (interactive)
+ (save-excursion
+ (goto-char (point-min))
+ (let ((newstatus (if (string= (eltuki-get-comment-status) "closed")
+ " open"
+ " closed")))
+ (if (re-search-forward "^#\\+COMMENTSTATUS:\\(.*\\)$" nil t)
+ (replace-match newstatus t t nil 1)
+ (when (search-forward "\n\n" nil t)
+ (backward-char))
+ (insert "#+COMMENTSTATUS:" newstatus "\n")))))
+
+(defun eltuki-slugify-string (str)
+ (while (string-match "[^a-zA-Z0-9 ]+" str)
+ (setq str (replace-match "" nil t str)))
+ (while (string-match " +" str)
+ (setq str (replace-match "-" nil t str)))
+ (downcase str))
+
+(defun eltuki-get-directory ()
+ (concat
+ eltuki-blog-dir "/"
+ (format-time-string "%Y%%2f%m%%2f%d%%2f")
+ (eltuki-slugify-string (eltuki-get-title))))
+
+(defun eltuki-write-content (dir)
+ (let ((org-export-with-toc nil)
+ (filename (concat dir "/content")))
+ (with-current-buffer (org-export-region-as-html
+ (point-min) (point-max) t "*eltuki-html*")
+ (write-region (point-min) (point-max) filename)
+ (kill-buffer))
+ filename))
+
+(defun eltuki-write-metadata (dir)
+ (let ((timestamp (eltuki-get-timestamp))
+ (tags (eltuki-get-tags))
+ (status (eltuki-get-status))
+ (title (eltuki-get-title))
+ (name (eltuki-slugify-string (eltuki-get-title)))
+ (commentstatus (eltuki-get-comment-status))
+ (filename (concat dir "/metadata")))
+ (with-temp-buffer
+ (insert "timestamp: " timestamp "\n"
+ "tags: " tags "\n"
+ "status: " status "\n"
+ "title: " title "\n"
+ "name: " name "\n"
+ "comment_status: " commentstatus)
+ (write-region (point-min) (point-max) filename))
+ filename))
+
+(defun eltuki-save-org (buffer dir)
+ (let ((filename (concat dir "/post.org")))
+ (with-current-buffer buffer
+ (write-file filename))
+ filename))
+
+(defun eltuki-git-add (file)
+ (shell-command (concat "cd " eltuki-blog-dir "; git add '" (expand-file-name file) "'")))
+
+(defun eltuki-commit ()
+ (shell-command (concat "cd " eltuki-blog-dir "; git commit -m \"new post: \\\"" (eltuki-get-title)
+ "\\\"\"")))
+
+(defun eltuki-finish ()
+ (interactive)
+ (let ((buffer (or (get-buffer "*eltuki*")
+ (current-buffer)))
+ (dest (eltuki-get-directory)))
+ (unless (file-exists-p dest)
+ (mkdir dest))
+
+ (mapc #'eltuki-git-add
+ (list (eltuki-write-content dest)
+ (eltuki-write-metadata dest)
+ (eltuki-save-org buffer dest)))
+
+ (eltuki-commit)
+ (kill-buffer buffer)))
+
+(provide 'eltuki)
+;;; eltuki.el ends here
diff --git a/emacs/site-lisp/ext.el b/emacs/site-lisp/ext.el
new file mode 100644
index 0000000..d6abaa6
--- /dev/null
+++ b/emacs/site-lisp/ext.el
@@ -0,0 +1,56 @@
+;;; ext.el --- More emacs functions
+
+;; Copyright (C) 2012 Tom Willemsen
+
+;; Author: Tom Willemsen <tom@ryuslash.org>
+;; Keywords: local
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program. If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;;
+
+;;; Code:
+
+(defadvice org-agenda-redo (after ext:org-agenda-redo-add-appts)
+ "Pressing `r' on the agenda will also add appointments."
+ (progn
+ (setq appt-time-msg-list nil)
+ (org-agenda-to-appt)))
+
+(defun ext:flymake-pyflakes-init ()
+ "Initialize function for flymake with pyflakes."
+ (let* ((temp-file (flymake-init-create-temp-buffer-copy
+ 'flymake-create-temp-inplace))
+ (local-file (file-relative-name temp-file (file-name-directory
+ buffer-file-name))))
+ (list "pycheck.sh" (list local-file))))
+
+(defun ext:comp-finish-function (buf str)
+ "Don't show compilation window if everything went ok"
+ (if (string-match "exited abnormally" str)
+ ;; there were errors
+ (message "compilation errors, press C-x ` to visit")
+ ;; no errors, make the compilation window go away in 0.5 seconds
+ (run-at-time 0.5 nil 'delete-windows-on buf)
+ (message "No compilation errors!")))
+
+(defun ext:reload-buffer ()
+ "Reload current buffer."
+ (interactive)
+ (revert-buffer nil t nil))
+
+(provide 'ext)
+;;; ext.el ends here
diff --git a/emacs/site-lisp/metalexpress.el b/emacs/site-lisp/metalexpress.el
new file mode 100644
index 0000000..0c4539a
--- /dev/null
+++ b/emacs/site-lisp/metalexpress.el
@@ -0,0 +1,80 @@
+;;; metalexpress.el --- Listen to Metal Express Radio
+
+;; Copyright (C) 2012 Tom Willemsen
+
+;; Author: Tom Willemsen <thomas@aethon.nl>
+;; Keywords: multimedia
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program. If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; Functions for easily listening to Metal Express Radio.
+
+;;; Code:
+
+(defgroup metal-express-radio nil
+ "Group for the Metal Express Radio listening functions."
+ :group 'multimedia)
+
+(defcustom metal-express-radio-playlist-url
+ "http://usa7-vn.mixstream.net/listen/8248.m3u"
+ "The URL of the Metal Express Radio stream."
+ :group 'metal-express-radio
+ :type 'string)
+
+(defcustom metal-express-radio-song-changed-hook nil
+ "Hook run when the currently playing song changes."
+ :type 'hook
+ :group 'metal-express-radio)
+
+(defvar metal-express-radio-currently-playing nil
+ "The currently playing song.")
+
+(defun mer-proc-filter (proc string)
+ (when (string-match "^ICY Info: StreamTitle='\\(.*\\)';StreamUrl='';"
+ string)
+ (setq metal-express-radio-currently-playing (match-string 1 string))
+ (apply 'run-hooks metal-express-radio-song-changed-hook)))
+
+(defun metal-express-radio-echo-currently-playing ()
+ (interactive)
+ (message metal-express-radio-currently-playing))
+
+(defun metal-express-radio-notify ()
+ (interactive)
+ (notifications-notify :title "Now playing:"
+ :body metal-express-radio-currently-playing))
+
+;;;###autoload
+(defun metal-express-radio-start ()
+ "Start listening to Metal Express Radio."
+ (interactive)
+ (let ((proc (start-process "metalexpress" "*Metal Express Radio*"
+ "mplayer" metal-express-radio-playlist-url)))
+ (set-process-filter proc #'mer-proc-filter)))
+
+(defun metal-express-radio-stop ()
+ "Stop listening to Metal Express Radio."
+ (interactive)
+ (kill-process (get-buffer-process "*Metal Express Radio*"))
+ (setq metal-express-radio-currently-playing nil))
+
+(add-hook 'metal-express-radio-song-changed-hook
+ 'metal-express-radio-echo-currently-playing)
+(add-hook 'metal-express-radio-song-changed-hook
+ 'metal-express-radio-notify)
+
+(provide 'metalexpress)
+;;; metalexpress.el ends here
diff --git a/emacs/site-lisp/mu4e-init.el b/emacs/site-lisp/mu4e-init.el
new file mode 100644
index 0000000..258a6ef
--- /dev/null
+++ b/emacs/site-lisp/mu4e-init.el
@@ -0,0 +1,54 @@
+;;; mu4e-init.el --- mu4e initialization
+
+;; Copyright (C) 2012 Tom Willemsen
+
+;; Author: Tom Willemsen <slash@drd>
+;; Keywords:
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program. If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;;
+
+;;; Code:
+
+(require 'oni)
+
+(oni:define-mailbox "aethon"
+ (oni:email thomas at aethon dot nl)
+ (expand-file-name "~/documents/work/aethon/signature.txt"))
+(oni:define-mailbox "gmail" (oni:email ryuslash at gmail dot com))
+(oni:define-mailbox "ninthfloor"
+ (oni:email ryuslash at ninthfloor dot org))
+(oni:define-mailbox "ryuslash" (oni:email tom at ryuslash dot org)
+ nil "ryuslash.org")
+
+(setq mu4e-headers-date-format "%d-%m %H:%M")
+(setq mu4e-headers-fields '((:date . 11)
+ (:flags . 6)
+ (:to . 22)
+ (:from . 22)
+ (:subject)))
+(setq mu4e-headers-show-threads nil)
+(setq mu4e-headers-sort-revert nil)
+(setq mu4e-html2text-command "w3m -dump -T text/HTML -cols 72")
+(setq mu4e-my-email-addresses (list
+ (oni:email tom at ryuslash dot org)
+ (oni:email ryuslash at gmail dot com)
+ (oni:email ryuslash at ninthfloor dot org)
+ (oni:email thomas at aethon dot nl)))
+
+(provide 'mu4e-init)
+;;; mu4e-init.el ends here
diff --git a/emacs/site-lisp/newsticker-init.el b/emacs/site-lisp/newsticker-init.el
new file mode 100644
index 0000000..c393df1
--- /dev/null
+++ b/emacs/site-lisp/newsticker-init.el
@@ -0,0 +1,6 @@
+(setq newsticker-automatically-mark-items-as-old nil)
+(setq newsticker-html-renderer 'w3m-region)
+(setq newsticker-obsolete-item-max-age 604800)
+(setq newsticker-use-full-width nil)
+
+(provide 'newsticker-init)
diff --git a/emacs/site-lisp/oni.el b/emacs/site-lisp/oni.el
new file mode 100644
index 0000000..80d1b01
--- /dev/null
+++ b/emacs/site-lisp/oni.el
@@ -0,0 +1,574 @@
+;;; oni.el --- Functions for emacs
+
+;; Copyright (C) 2012 Tom Willemsen
+
+;; Author: Tom Willemsen <tom@ryuslash.org>
+;; Keywords: local
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program. If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;;
+
+;;; Code:
+
+(autoload 'notifications-notify "notifications")
+(autoload 'jabber-send-message "jabber-chat")
+
+(defmacro oni:email (user at host dot com)
+ "Turn arguments into an email address.
+The resulting email address will look like: USER@HOST.COM, AT and
+DOT are intentionally being skipped."
+ (concat (symbol-name user) "@" (symbol-name host) "."
+ (symbol-name com)))
+
+(defun oni:after-save-func ()
+ "Function for `after-save-hook'."
+ (oni:compile-el)
+ (executable-make-buffer-file-executable-if-script-p)
+ (let* ((dom-dir (locate-dominating-file (buffer-file-name) "Makefile"))
+ (TAGSp (not (string= "" (shell-command-to-string
+ (concat "grep \"^TAGS:\" " dom-dir "Makefile"))))))
+ (when (and dom-dir TAGSp)
+ (shell-command
+ (concat "make -C " dom-dir " TAGS >/dev/null 2>&1")))))
+
+(defun oni:appt-display-window-and-jabber (min-to-app new-time appt-msg)
+ "Send a message to my phone jabber account."
+ (jabber-send-message (car jabber-connections) "phone@ryuslash.org"
+ nil (format "%s%s (in %s minutes)"
+ new-time appt-msg min-to-app) nil)
+ (appt-disp-window min-to-app new-time appt-msg))
+;; (jabber-send-message (car jabber-connections)
+;; "aethon@muc.ryuslash.org" nil "Hi, I'm a programmatic message; this
+;; upens up possibilities :)" "groupchat")
+(defun oni:before-save-func ()
+ "Function for `before-save-hook'."
+ (if (eq major-mode 'html-mode)
+ (oni:replace-html-special-chars))
+ (if (not (eq major-mode 'markdown-mode))
+ (delete-trailing-whitespace)))
+
+(defun oni:c-mode-func ()
+ "Function for `c-mode-hook'."
+ (local-set-key [f9] 'compile)
+ (local-set-key "\C-j" 'oni:newline-and-indent))
+
+(defun oni:close-client-window ()
+ "Close a client's frames."
+ (interactive)
+ (server-save-buffers-kill-terminal nil))
+
+(defun oni:color-for (object)
+ "Generate a hex color by taking the first 6 characters of OBJECT's MD5 sum."
+ (format "#%s" (substring (md5 object) 0 6)))
+
+(defun oni:compile-el ()
+ "Compile the current buffer file if it is an .el file."
+ (let* ((full-file-name (buffer-file-name))
+ (file-name (file-name-nondirectory full-file-name))
+ (suffix (file-name-extension file-name)))
+ (if (and (not (string-equal file-name ".dir-locals.el"))
+ (string-equal suffix "el"))
+ (byte-compile-file full-file-name))))
+
+(defun oni:css-mode-func ()
+ "Function for `css-mode-hook'."
+ (local-set-key "\C-j" 'oni:newline-and-indent)
+ (rainbow-mode))
+
+(defun oni:current-jabber-status ()
+ "Return a string representing the current jabber status."
+ (or (and (not *jabber-connected*) "Offline")
+ (and (not (string= *jabber-current-status* ""))
+ *jabber-current-status*)
+ "Online"))
+
+(defun oni:diary-display-func ()
+ "Function for `diary-display-hook'."
+ (diary-fancy-display))
+
+(defun oni:emacs-lisp-mode-func ()
+ "Function for `emacs-lisp-mode-hook'."
+ (eldoc-mode))
+
+(defun oni:emacs-startup-func ()
+ "Function for `emacs-init-hook'."
+ (require 'auto-complete-config)
+ (ac-config-default))
+
+(defun oni:go-mode-func ()
+ "Function for `go-mode-hook'."
+ (setq indent-tabs-mode nil)
+ (local-set-key "\C-j" 'oni:newline-and-indent))
+
+(defun oni:gtags-mode-func ()
+ "Function for `gtags-mode-hook'."
+ (local-set-key "\M-," 'gtags-find-tag)
+ (local-set-key "\M-." 'gtags-find-rtag))
+
+(defun oni:haskell-mode-func ()
+ "Function for `haskell-mode-hook'."
+ (turn-on-haskell-indentation))
+
+(defun oni:html-mode-func ()
+ "Function for `html-mode-hook'."
+ (yas-minor-mode)
+ (fci-mode)
+ (flycheck-mode))
+
+(defun oni:ido-init ()
+ "Initialization functionn for ido."
+ (setq ido-ignore-buffers
+ (list "^\\` " "^irc\\." "^\\#" "^\\*Customize Option:"
+ (eval-when-compile
+ (regexp-opt
+ '("*-jabber-roster-*"
+ "*Messages*"
+ "*fsm-debug*"
+ "*magit-process*"
+ "*magit-edit-log*"
+ "*Backtrace*"))))))
+
+(defun oni:indent-shift-left (start end &optional count)
+ "Rigidly indent region.
+Region is from START to END. Move
+COUNT number of spaces if it is non-nil otherwise use
+`tab-width'."
+ (interactive
+ (if mark-active
+ (list (region-beginning) (region-end) current-prefix-arg)
+ (list (line-beginning-position)
+ (line-end-position)
+ current-prefix-arg)))
+ (if count
+ (setq count (prefix-numeric-value count))
+ (setq count tab-width))
+ (when (> count 0)
+ (let ((deactivate-mark nil))
+ (save-excursion
+ (goto-char start)
+ (while (< (point) end)
+ (if (and (< (current-indentation) count)
+ (not (looking-at "[ \t]*$")))
+ (error "Can't shift all lines enough"))
+ (forward-line))
+ (indent-rigidly start end (- count))))))
+
+(defun oni:indent-shift-right (start end &optional count)
+ "Indent region between START and END rigidly to the right.
+If COUNT has been specified indent by that much, otherwise look at
+`tab-width'."
+ (interactive
+ (if mark-active
+ (list (region-beginning) (region-end) current-prefix-arg)
+ (list (line-beginning-position)
+ (line-end-position)
+ current-prefix-arg)))
+ (let ((deactivate-mark nil))
+ (if count
+ (setq count (prefix-numeric-value count))
+ (setq count tab-width))
+ (indent-rigidly start end count)))
+
+(defun oni:jabber-alert-message-func (from buffer text title)
+ (notifications-notify :title title
+ :body text))
+
+(defun oni:jabber-chat-mode-func ()
+ "Function for `jabber-chat-mode-hook'."
+ (visual-line-mode)
+ (setq mode-line-format (append (cddr jabber-chat-header-line-format)
+ '(global-mode-string))
+ header-line-format nil))
+
+(defun oni:jabber-init ()
+ "Initialization function for jabber."
+ (remove-hook 'jabber-alert-presence-hooks 'jabber-presence-echo))
+
+(defun oni:jabber-roster-mode-func ()
+ "Function for `jabber-roster-mode-hook'."
+ (setq mode-line-format
+ (list (propertize " %m" 'face 'mode-line-buffer-id))))
+
+(defun oni:java-mode-func ()
+ "Function for `java-mode-hook'."
+ (local-set-key "\C-j" 'oni:newline-and-indent))
+
+(defun oni:js-mode-func ()
+ "Function for `js-mode-hook'."
+ (rainbow-delimiters-mode)
+ (local-set-key "\C-j" 'oni:newline-and-indent))
+
+(defun oni:js2-mode-func ()
+ "Function for `js2-mode-hook'."
+ (oni:prog-mode-func)
+ (oni:js-mode-func)
+ (local-set-key (kbd "<f5>") #'slime-js-reload)
+ (slime-js-minor-mode))
+
+(defun oni:kill-region-or-backward-char ()
+ "Either `kill-region' or `backward-delete-char-untabify'."
+ (interactive)
+ (if (region-active-p)
+ (kill-region (region-beginning) (region-end))
+ (backward-delete-char-untabify 1)))
+
+(defun oni:kill-region-or-forward-char ()
+ "Either `kill-region' or `delete-forward-char'."
+ (interactive)
+ (if (region-active-p)
+ (kill-region (region-beginning) (region-end))
+ (delete-forward-char 1)))
+
+(defun oni:kill-region-or-line ()
+ "Either `kill-region' or `kill-line'."
+ (interactive)
+ (if (region-active-p)
+ (kill-region (region-beginning) (region-end))
+ (kill-line)))
+
+(defun oni:lua-mode-func()
+ "Function for `lua-mode-hook'."
+ (local-unset-key (kbd ")"))
+ (local-unset-key (kbd "]"))
+ (local-unset-key (kbd "}"))
+ (flycheck-mode))
+
+(defun oni:magit-log-edit-mode-func ()
+ "Function for `magit-log-edit-mode-hook'."
+ (auto-fill-mode)
+ (font-lock-add-keywords
+ nil
+ '(("\\`\\(.\\{,50\\}\\)\\(.*\\)\n?\\(.*\\)$"
+ (1 'git-commit-summary-face)
+ (2 'git-commit-overlong-summary-face)
+ (3 'git-commit-nonempty-second-line-face))
+ ("`\\([^']+\\)'" 1 font-lock-constant-face))
+ t))
+
+(defun oni:markdown-mode-func ()
+ "Function for `markdown-mode-hook'."
+ (setq-local comment-auto-fill-only-comments nil)
+ (setq-local whitespace-style '(face trailing))
+ (auto-fill-mode)
+ (whitespace-mode))
+
+(defun oni:message-mode-func ()
+ "Function for `message-mode-hook'."
+ (setq-local comment-auto-fill-only-comments nil)
+ (auto-fill-mode)
+ (flyspell-mode))
+
+(defun oni:mini-fix-timestamp-string (date-string)
+ "A minimal version of Xah Lee's `fix-timestamp-string'.
+Turn DATE-STRING into something else that can be worked with in
+code. Found at http://xahlee.org/emacs/elisp_parse_time.html"
+ (setq date-string (replace-regexp-in-string "Jan" "01" date-string)
+ date-string (replace-regexp-in-string "Feb" "02" date-string)
+ date-string (replace-regexp-in-string "Mar" "03" date-string)
+ date-string (replace-regexp-in-string "Apr" "04" date-string)
+ date-string (replace-regexp-in-string "May" "05" date-string)
+ date-string (replace-regexp-in-string "Jun" "06" date-string)
+ date-string (replace-regexp-in-string "Jul" "07" date-string)
+ date-string (replace-regexp-in-string "Aug" "08" date-string)
+ date-string (replace-regexp-in-string "Sep" "09" date-string)
+ date-string (replace-regexp-in-string "Oct" "10" date-string)
+ date-string (replace-regexp-in-string "Nov" "11" date-string)
+ date-string (replace-regexp-in-string "Dec" "12" date-string))
+ (string-match
+ "^\\([0-9]\\{2\\}\\)-\\([0-9]\\{2\\}\\)-\\([0-9]\\{4\\}\\)$"
+ date-string)
+ (format "%s-%s-%s"
+ (match-string 3 date-string)
+ (match-string 2 date-string)
+ (match-string 1 date-string)))
+
+(defun oni:move-beginning-of-dwim ()
+ "Move to beginning of line either after indentation or before."
+ (interactive)
+ (let ((start (point)))
+ (back-to-indentation)
+ (if (= start (point))
+ (beginning-of-line))))
+
+(defun oni:move-end-of-dwim ()
+ "Move to end of line, either before any comments or after."
+ (interactive)
+ (let ((start (point))
+ (eolpos (line-end-position)))
+ (beginning-of-line)
+ (if (and comment-start
+ (comment-search-forward eolpos t))
+ (progn
+ (search-backward-regexp (concat "[^ \t" comment-start "]"))
+ (forward-char)
+
+ (when (or (bolp)
+ (= start (point)))
+ (end-of-line)))
+ (end-of-line))))
+
+(defun oni:myepisodes-formatter (plist)
+ "Format RSS items from MyEpisodes as org tasks.
+PLIST contains all the pertinent information."
+ (let ((str (plist-get plist :title)))
+ (string-match
+ "^\\[ \\([^\]]+\\) \\]\\[ \\([^\]]+\\) \\]\\[ \\([^\]]+\\) \\]\\[ \\([^\]]+\\) \\]$"
+ str)
+ (let* ((title (match-string 1 str))
+ (episode (match-string 2 str))
+ (name (match-string 3 str))
+ (date (oni:mini-fix-timestamp-string (match-string 4 str))))
+ (format "* ACQUIRE %s %s - %s \n SCHEDULED: <%s>"
+ title episode name date))))
+
+(defun oni:newline-and-indent ()
+ "`newline-and-indent', but with a twist.
+When dealing with braces, add another line and indent that too."
+ (interactive)
+ (if (and (not (or (= (point) (point-max))
+ (= (point) (point-min))))
+ (or (and (char-equal (char-before) ?{)
+ (char-equal (char-after) ?}))
+ (and (char-equal (char-before) ?\()
+ (char-equal (char-after) ?\)))))
+ (save-excursion (newline-and-indent)))
+ (newline-and-indent))
+
+(defun oni:org-mode-func ()
+ "Function for `org-mode-hook'."
+ (auto-fill-mode)
+ (yas-minor-mode)
+ (setq-local comment-auto-fill-only-comments nil))
+
+(defun oni:php-mode-func ()
+ "Function for `php-mode-hook'."
+ (local-set-key "\C-j" 'oni:newline-and-indent)
+ (c-set-offset 'arglist-intro '+)
+ (c-set-offset 'arglist-close '0)
+ (rainbow-delimiters-mode)
+ (setq-local fci-rule-column 80)
+ (flycheck-mode))
+
+(defun oni:prog-mode-func ()
+ "Function for `prog-mode-hook'."
+ (rainbow-delimiters-mode)
+ (fci-mode)
+ (yas-minor-mode)
+ (auto-fill-mode))
+
+(defun oni:python-mode-func ()
+ "Function for `python-mode-hook'."
+ (flycheck-mode)
+ (local-set-key (kbd "C->") 'python-indent-shift-right)
+ (local-set-key (kbd "C-<") 'python-indent-shift-left)
+ (set (make-local-variable 'electric-indent-chars) nil)
+ (rainbow-delimiters-mode)
+ (setq fci-rule-column 79
+ fill-column 72)
+ (setq-local whitespace-style '(tab-mark))
+ (fci-mode)
+ (whitespace-mode))
+
+(defun oni:rainbow-mode-init ()
+ "Initialization function for rainbow-mode."
+ (diminish 'rainbow-mode))
+
+(defun oni:raise-ansi-term (arg)
+ "Create or show an `ansi-term' buffer."
+ (interactive "P")
+ (let ((buffer (get-buffer "*ansi-term*")))
+ (if (and buffer (not arg))
+ (switch-to-buffer buffer)
+ (call-interactively 'ansi-term))))
+
+(defun oni:raise-scratch (&optional mode)
+ "Show the *scratch* buffer.
+If called with a universal argument, ask the user which mode to
+use. If MODE is not nil, open a new buffer with the name
+*MODE-scratch* and load MODE as its major mode."
+ (interactive (list (if current-prefix-arg
+ (read-string "Mode: ")
+ nil)))
+ (let* ((bname (if mode
+ (concat "*" mode "-scratch*")
+ "*scratch*"))
+ (buffer (get-buffer bname))
+ (mode-sym (intern (concat mode "-mode"))))
+
+ (unless buffer
+ (setq buffer (generate-new-buffer bname))
+ (with-current-buffer buffer
+ (when (fboundp mode-sym)
+ (funcall mode-sym))))
+
+ (select-window (display-buffer buffer))))
+
+(defun oni:replace-html-special-chars ()
+ "Replace special characters with HTML escaped entities."
+ (oni:replace-occurrences "é" "&eacute;"))
+
+(defun oni:replace-occurrences (from to)
+ "Replace all occurrences of FROM with TO in the current buffer."
+ (save-excursion
+ (goto-char (point-min))
+ (while (search-forward from nil t)
+ (replace-match to))))
+
+(defun oni:request-pull ()
+ "Start a mail to request pulling from a git repository."
+ (interactive)
+ (let* ((default-directory
+ (expand-file-name
+ (or (locate-dominating-file default-directory ".git")
+ (magit-read-top-dir nil))))
+ (refs (magit-list-interesting-refs magit-uninteresting-refs))
+ (from (cdr (assoc (completing-read "From: " refs) refs)))
+ (url (read-from-minibuffer "Pull URL: "))
+ (to (symbol-name (read-from-minibuffer "Up to (HEAD): "
+ nil nil t nil "HEAD")))
+ (patchp (and current-prefix-arg (listp current-prefix-arg))))
+ (message "Requesting pull for %s from %s to %s at %s with%s patch"
+ default-directory from to url (if patchp "" "out"))
+
+ (compose-mail
+ nil (concat
+ "Requesting pull for "
+ (file-name-base (directory-file-name default-directory))))
+
+ (save-excursion
+ (goto-char (point-max))
+ (insert
+ (shell-command-to-string
+ (concat "git --git-dir='" default-directory ".git' --work-tree='"
+ default-directory "' request-pull " (when patchp "-p ")
+ from " " url " " to))))))
+
+(defun oni:rst-mode-func ()
+ "Function for `rst-mode-hook'."
+ (auto-fill-mode))
+
+(defun oni:self-insert-dwim ()
+ "Execute self insert, but when the region is active call self
+insert at the end of the region and at the beginning."
+ (interactive)
+ (if (region-active-p)
+ (let ((electric-pair-mode nil)
+ (beginning (region-beginning))
+ (end (region-end)))
+ (goto-char end)
+ (self-insert-command 1)
+ (save-excursion
+ (goto-char beginning)
+ (self-insert-command 1)))
+ (self-insert-command 1)))
+
+(defun oni:shorten-dir (dir)
+ "Shorten a directory, (almost) like fish does it."
+ (while (string-match "\\(/\\.?[^./]\\)[^/]+/" dir)
+ (setq dir (replace-match "\\1/" nil nil dir)))
+ dir)
+
+(defun oni:show-buffer-position ()
+ "Show the position in the current buffer."
+ (interactive)
+ (message (format "%d:%d" (line-number-at-pos) (current-column))))
+
+(defun oni:show-org-index ()
+ "Show the index of my org files."
+ (interactive)
+ (find-file "~/documents/org/index.org"))
+
+(defun oni:smex-init ()
+ "Initialization function for smex."
+ (global-set-key (kbd "M-x") 'smex)
+ (global-set-key (kbd "C-M-x") 'smex-major-mode-commands))
+
+(defun oni:split-window-interactive (dir)
+ "Split windows in direction DIR.
+
+Can also delete or switch to another window."
+ (interactive
+ (list (read-char "Direction (h,v,q,d,o): ")))
+ (case dir
+ ((?v) (split-window-vertically))
+ ((?h) (split-window-horizontally))
+ ((?q) (delete-other-windows))
+ ((?d) (delete-window))
+ ((?o) (other-window 1))))
+
+(defun oni:split-window-interactively (window)
+ "Ask for a direction and split WINDOW that way.
+
+If no direction is given, don't split."
+ (let ((dir (read-char "Direction (h,v): ")))
+ (case dir
+ ((?v) (split-window-vertically))
+ ((?h) (split-window-horizontally))
+ (t window))))
+
+(defun oni:start-python-test-mail-server ()
+ "Run the python test mailserver."
+ (interactive)
+ (start-process "python-test-mail-server" "*py-mail-server*" "python" "-m"
+ "smtpd" "-n" "-c" "DebuggingServer" "localhost:1025"))
+
+(defun oni:stop-python-test-mail-server ()
+ "Stop the python test mailserver."
+ (interactive)
+ (kill-process "python-test-mail-server"))
+
+(defun oni:term-mode-func ()
+ "Function for `term-mode-hook'."
+ (setq truncate-lines nil))
+
+(defun oni:texinfo-mode-func ()
+ "Function for `texinfo-mode-hook'."
+ (setq-local comment-auto-fill-only-comments nil)
+ (auto-fill-mode))
+
+(defun oni:write-file-func ()
+ "Function for `write-file-hooks'."
+ (time-stamp))
+
+(defun oni:yas-minor-mode-func ()
+ "Function for `yas-minor-mode-hook'."
+ (define-key yas-minor-mode-map (kbd "TAB") nil)
+ (define-key yas-minor-mode-map [(tab)] nil)
+ (define-key yas-minor-mode-map (kbd "C-\\") 'yas-expand))
+
+(defun oni:yasnippet-init ()
+ "Initialization function for yasnippet."
+ (diminish 'yas-minor-mode))
+
+(defvar oni:auto-save-name-transforms
+ `((".*" ,temporary-file-directory t))
+ "Place all auto-save files in `temporary-file-directory'.")
+
+(defvar oni:backup-directory-alist
+ `((".*" . ,temporary-file-directory))
+ "Palce all backup files in `temporary-file-directory'.")
+
+(defvar oni:mailbox-map
+ '("top" ("menu"
+ ("ryulash.org" . "ryuslash")
+ ("ninthfloor" . "ninthfloor")
+ ("gmail" . "gmail")
+ ("aethon" . "aethon")))
+ "A mailbox map for use with `tmm-prompt'.")
+
+(provide 'oni)
+;;; oni.el ends here
diff --git a/emacs/site-lisp/org-init.el b/emacs/site-lisp/org-init.el
new file mode 100644
index 0000000..4033c30
--- /dev/null
+++ b/emacs/site-lisp/org-init.el
@@ -0,0 +1,164 @@
+;;; org-init.el --- Org initialization
+
+;; Copyright (C) 2012 Tom Willemsen
+
+;; Author: Tom Willemsen <slash@drd>
+;; Keywords:
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program. If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;;
+
+;;; Code:
+
+(require 'appt)
+(require 'oni)
+(require 'org-contacts)
+(require 'org-habit)
+(require 'org-protocol)
+
+(autoload 'org-clocking-p "org-clock")
+
+(eval-after-load "org-crypt"
+ '(org-crypt-use-before-save-magic))
+
+(defun oni:note-template ()
+ (concat
+ "* %<%c>\n"
+ " :DIRECTORY: =" default-directory "=\n"
+ (when (buffer-file-name) " :FILE: [[file:%F][%F]]\n")
+ (when (org-clocking-p) " :TASK: %K\n")
+ "\n %?"))
+
+(defun oni:org-maybe-outline-path ()
+ (let ((outline-path (org-format-outline-path (org-get-outline-path))))
+ (unless (string= outline-path "")
+ (setq outline-path (concat "[ " outline-path " ] ")))
+ outline-path))
+
+(defun oni:set-org-agenda-files ()
+ "Set `org-agenda-files` according to the current time."
+ (interactive)
+ (let* ((current-time (decode-time))
+ (current-hour (nth 2 current-time))
+ (current-dow (nth 6 current-time)))
+ (if (or (= current-dow 6) (= current-dow 0) ; Saturday or Sunday
+ (< current-hour 9) (>= current-hour 17))
+ (setq org-agenda-files
+ (append oni:personal-agenda-files oni:common-agenda-files))
+ (setq org-agenda-files
+ (append oni:work-agenda-files oni:common-agenda-files)))))
+
+(defvar oni:personal-agenda-files
+ (list (expand-file-name "~/documents/org/tasks"))
+ "My personal agenda, should only show up at times I don't have
+ to work.")
+
+(defvar oni:work-agenda-files
+ (list (expand-file-name "~/documents/org/work"))
+ "My work agenda, should only show up at times I work.")
+
+(defvar oni:common-agenda-files
+ (list (expand-file-name "~/documents/org/dailies")
+ (expand-file-name "~/documents/org/misc/contacts.org")
+ (expand-file-name "~/documents/org/misc/bookmarks.org"))
+ "Agenda files that are work-agnostic, should always show up.")
+
+(setq org-agenda-custom-commands
+ '(("P" . "Personal only")
+ ("Pa" "Personal agenda" agenda ""
+ ((org-agenda-files (append oni:personal-agenda-files
+ oni:common-agenda-files))))
+ ("Pt" "Personal todo" todo ""
+ ((org-agenda-files (append oni:personal-agenda-files
+ oni:common-agenda-files))))
+ ("W" . "Work only")
+ ("Wa" "Work agenda" agenda ""
+ ((org-agenda-files (append oni:work-agenda-files
+ oni:common-agenda-files))))
+ ("Wt" "Work todo" todo ""
+ ((org-agenda-files (append oni:work-agenda-files
+ oni:common-agenda-files))))))
+(setq org-agenda-prefix-format
+ '((agenda . " %i %-12:c%?-12t% s")
+ (timeline . " % s")
+ (todo . " %i %-12:c %(oni:org-maybe-outline-path)")
+ (tags . " %i %-12:c %(oni:org-maybe-outline-path)")
+ (search . " %i %-12:c")))
+(setq org-agenda-sorting-strategy
+ '((agenda habit-down time-up priority-down category-keep)
+ (todo priority-down category-keep)
+ (tags priority-down category-keep)
+ (search category-keep)))
+(setq org-agenda-tags-column -101)
+(setq org-directory (expand-file-name "~/documents/org"))
+(setq org-default-notes-file (concat org-directory "/org"))
+(setq org-capture-templates
+ `(("t" "Task" entry (file "~/documents/org/tasks")
+ "* TODO %?")
+ ("T" "Linked task" entry (file "~/documents/org/tasks")
+ "* TODO %?\n\n %a")
+ ("n" "General note" entry (file ,org-default-notes-file)
+ (function oni:note-template))))
+(setq org-contacts-files '("~/documents/org/misc/contacts.org"))
+(setq org-agenda-show-outline-path nil)
+(setq org-agenda-todo-ignore-deadlines 'far)
+(setq org-agenda-todo-ignore-scheduled t)
+(setq org-export-htmlize-output-type 'css)
+(setq org-feed-alist
+ '(("MyEpisodes"
+ "http://www.myepisodes.com/rss.php?feed=mylist&uid=Slash&pwdmd5=04028968e1f0b7ee678b748a4320ac17"
+ "~/documents/org/tasks" "MyEpisodes"
+ :formatter oni:myepisodes-formatter)))
+(setq org-fontify-done-headline t)
+(setq org-hide-emphasis-markers t)
+(setq org-outline-path-complete-in-steps t)
+(setq org-refile-allow-creating-parent-nodes t)
+(setq org-refile-targets '((nil . (:maxlevel . 6))))
+(setq org-refile-use-outline-path 'file)
+(setq org-return-follows-link t)
+(setq org-src-fontify-natively t)
+(setq org-tags-column -101)
+(setq org-tags-exclude-from-inheritance '("crypt"))
+(setq org-todo-keyword-faces
+ '(("TODO" :foreground "#ff756e" :background "#171719" :box (:width 1 :color "#282830"))
+ ("DONE" :foreground "#9ad870" :background "#222224" :box (:width 1 :color "#333335"))
+ ("SUCCEEDED" :foreground "#9ad870" :background "#222224" :box (:width 1 :color "#333335"))
+ ("WAITING" :foreground "#ffbb56" :background "#171719" :box (:width 1 :color "#282830"))
+ ("CANCELLED" :foreground "#93d8d8" :background "#222224" :box (:width 1 :color "#333335"))
+ ("FAILED" :foreground "#93d8d8" :background "#222224" :box (:width 1 :color "#333335"))
+ ("WIP" :foreground "#ff756e" :background "#171719" :box (:width 1 :color "#282830"))
+ ("HOLD" :foreground "#ffbb56" :background "#171719" :box (:width 1 :color "#282830"))
+ ("ACQUIRE" :foreground "#ff756e" :background "#171719" :box (:width 1 :color "#282830"))
+ ("IGNORED" :foreground "#999999" :background "#222224" :box (:width 1 :color "#333335"))))
+(setq org-use-fast-todo-selection t)
+(setq org-use-property-inheritance '("slug"))
+
+(add-hook 'org-agenda-mode-hook 'org-agenda-to-appt)
+
+(add-to-list 'org-modules 'habit)
+
+(org-indent-mode t)
+
+(org-agenda-to-appt)
+(ad-activate 'org-agenda-redo)
+
+(oni:set-org-agenda-files)
+(run-at-time "09:01" (* 60 60 24) 'oni:set-org-agenda-files)
+(run-at-time "17:01" (* 60 60 24) 'oni:set-org-agenda-files)
+
+(provide 'org-init)
+;;; org-init.el ends here
diff --git a/emacs/site-lisp/quick-edit-mode.el b/emacs/site-lisp/quick-edit-mode.el
new file mode 100644
index 0000000..821c738
--- /dev/null
+++ b/emacs/site-lisp/quick-edit-mode.el
@@ -0,0 +1,74 @@
+;;; quick-edit-mode.el --- Quickly edit stuff
+
+;; Copyright (C) 2012 Tom Willemsen
+
+;; Author: Tom Willemsen <slash@drd>
+;; Keywords: convenience
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program. If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; Quickly edit stuff
+
+;;; Code:
+
+(defvar quick-edit-map
+ (let ((map (make-sparse-keymap)))
+ (define-key map "/" 'undo)
+ (define-key map "0" 'delete-window)
+ (define-key map "1" 'delete-other-windows)
+ (define-key map "2" 'split-window-below)
+ (define-key map "3" 'split-window-right)
+ (define-key map "K" 'kill-whole-line)
+ (define-key map "V" 'scroll-down-command)
+ (define-key map "a" 'oni:move-beginning-of-dwim)
+ (define-key map "b" 'backward-char)
+ (define-key map "d" 'oni:kill-region-or-forward-char)
+ (define-key map "e" 'oni:move-end-of-dwim)
+ (define-key map "f" 'forward-char)
+ (define-key map "j" 'newline-and-indent)
+ (define-key map "k" 'oni:kill-region-or-line)
+ (define-key map "n" 'next-line)
+ (define-key map "o" 'other-window)
+ (define-key map "p" 'previous-line)
+ (define-key map "v" 'scroll-up-command)
+ (define-key map "w" 'oni:kill-region-or-backward-char)
+ (define-key map (kbd "C-b") 'electric-buffer-list)
+ (define-key map (kbd "C-g") 'quick-edit-mode)
+ (define-key map (kbd "RET") 'quick-edit-mode)
+ map)
+ "Keymap for quick-edit-mode.")
+
+(defun qe-locally-disable ()
+ "Disable quick-edit mode in the minibuffer"
+ (when (eq overriding-local-map quick-edit-map)
+ (setq-local overriding-local-map nil)))
+
+;;;###autoload
+(define-minor-mode quick-edit-mode
+ "Quickly edit stuff."
+ :lighter " qe"
+ :global t
+ (if quick-edit-mode
+ (progn
+ (setq overriding-local-map quick-edit-map)
+ (add-hook 'minibuffer-setup-hook 'qe-locally-disable)
+ (add-hook 'special-mode-hook 'qe-locally-disable))
+ (setq overriding-local-map nil)
+ (remove-hook 'minibuffer-setup-hook 'qe-locally-disable)
+ (remove-hook 'special-mode-hook 'qe-locally-disable)))
+
+(provide 'quick-edit-mode)
+;;; quick-edit-mode.el ends here
diff --git a/emacs/site-lisp/wm-init.el b/emacs/site-lisp/wm-init.el
new file mode 100644
index 0000000..694acab
--- /dev/null
+++ b/emacs/site-lisp/wm-init.el
@@ -0,0 +1,3 @@
+(async-shell-command "herbstluftwm" " herbstluftwm")
+(async-shell-command "dunst" " dunst")
+(async-shell-command "xbindkeys" " xbindkeys")
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2024-06-18 12:42:53 +0000