Restructure emacs configuration

5 files changed, 1232 insertions, 0 deletions

diff --git a/emacs/Makefile b/emacs/Makefile
new file mode 100644
index 0000000..45151ef
--- /dev/null
+++ b/emacs/Makefile
@@ -0,0 +1,24 @@
+EMACS = emacs
+
+files = init.el init.elc
+install-files = $(addprefix install-,$(files))
+submodules = eshell
+install-submodules = $(addprefix install-,$(submodules))
+
+.PHONY: all $(submodules) install $(install-submodules) $(install-files)
+
+all: $(files) $(submodules)
+
+$(submodules):
+	$(MAKE) -C $@/
+
+$(filter %.elc,$(files)): %.elc: %.el
+	$(EMACS) -batch -eval "(byte-compile-file \"$^\")"
+
+install: $(install-files) $(install-submodules)
+
+$(install-files): install-%:
+	install -Dm 444 $* ${HOME}/.emacs.d/$*
+
+$(install-submodules): install-%:
+	$(MAKE) -C $*/ install
diff --git a/emacs/eshell/Makefile b/emacs/eshell/Makefile
new file mode 100644
index 0000000..a28a794
--- /dev/null
+++ b/emacs/eshell/Makefile
@@ -0,0 +1,6 @@
+.PHONY: all install
+
+all:
+
+install:
+	install -Dm 444 alias ${HOME}/.emacs.d/eshell/alias
diff --git a/emacs/eshell/alias b/emacs/eshell/alias
new file mode 100644
index 0000000..940108a
--- /dev/null
+++ b/emacs/eshell/alias
@@ -0,0 +1,8 @@
+alias git git --no-pager $*
+alias rm rm -v $*
+alias sudo *sudo $*
+alias ncmpcpp ansi-term ncmpcpp ncmpcpp
+alias listen eshell-exec-visual mplayer http://usa7-vn.mixstream.net/listen/8248.pls
+alias o find-file $1
+alias d dired $1
+alias newsbeuter ansi-term newsbeuter newsbeuter
diff --git a/emacs/gnus.el b/emacs/gnus.el
new file mode 100644
index 0000000..1bf988a
--- /dev/null
+++ b/emacs/gnus.el
@@ -0,0 +1,70 @@
+;; -*- eval: (git-auto-commit-mode 1) -*-
+(setq gnus-select-method '(nntp "news.eternal-september.org"))
+(setq gnus-secondary-select-methods
+      '((nnmaildir "gmail"
+                   (directory "~/documents/mail/gmail/"))
+        (nnmaildir "ninthfloor"
+                   (directory "~/documents/mail/ninthfloor/"))
+        (nnmaildir "arch"
+                   (directory "~/documents/mail/arch/"))
+        (nnmaildir "aethon"
+                   (directory "~/documents/mail/aethon/"))
+        (nnmaildir "ryuslash"
+                   (directory "~/documents/mail/ryuslash.org/"))
+        (nntp "news.gmane.org")))
+
+(setq gnus-auto-subscribed-groups nil)
+(setq gnus-save-newsrc-file nil)
+(setq gnus-read-newsrc-file nil)
+(setq gnus-novice-user t)
+(setq gnus-article-truncate-lines nil)
+
+(setq message-send-mail-function 'message-send-mail-with-sendmail)
+(setq sendmail-program "/usr/bin/msmtp")
+(setq message-sendmail-extra-arguments '("-a" "gmail"))
+
+;; (setq gnus-parameters
+;;       '(("gmail"
+;;          (display . all))
+;;         ("aethon"
+;;          (display . all)
+;;         ("arch"
+;;          (display . all)))))
+
+(setq gnus-permanently-visible-groups
+      "\\(gmail\\|aethon\\|arch\\|ninthfloor\\|ryuslash\\):INBOX")
+
+(setq nntp-marks-is-evil t)
+
+(setq gnus-check-new-newsgroups nil)
+
+(setq gnus-posting-styles
+      '((".*"
+         (address "ryuslash@gmail.com")
+         (eval (setq message-sendmail-extra-arguments '("-a" "gmail"))))
+        ("ninthfloor:"
+         (address "ryuslash@ninthfloor.org")
+         (eval (setq message-sendmail-extra-arguments '("-a" "ninthfloor"))))
+        ("arch:"
+         (address "tom.willemsen@archlinux.us")
+         (eval (setq message-sendmail-extra-arguments '("-a" "arch"))))
+        ("aethon:"
+         (address "thomas@aethon.nl")
+         (signature-file "~/documents/work/aethon/signature.txt")
+         (eval (setq message-sendmail-extra-arguments '("-a" "aethon"))))
+        ("ryuslash:"
+         (address "tom@ryuslash.org")
+         (eval (setq message-sendmail-extra-arguments '("-a" "ryuslash"))))))
+
+(setq user-mail-address "ryuslash@gmail.com")
+(setq user-full-name "Tom Willemsen")
+
+(add-hook 'gnus-summary-mode-hook '(lambda () (linum-mode -1)))
+(add-hook 'gnus-article-mode-hook '(lambda () (linum-mode -1)))
+(add-hook 'gnus-group-mode-hook '(lambda () (linum-mode -1)))
+
+;-----[ BBDB ]--------------------------------------------------------
+(require 'bbdb)
+(bbdb-initialize 'gnus 'message)
+(bbdb-insinuate-gnus)
+(setq bbdb-north-american-phone-numbers-p nil)
diff --git a/emacs/init.el b/emacs/init.el
new file mode 100644
index 0000000..9dadf1c
--- /dev/null
+++ b/emacs/init.el
@@ -0,0 +1,1124 @@
+(eval-and-compile
+  (package-initialize)
+
+  (mapc #'(lambda (directory)
+	    (add-to-list 'load-path directory)
+	    (let ((default-directory directory))
+	      (normal-top-level-add-subdirs-to-load-path)))
+	'("/usr/share/emacs/site-lisp" "~/.emacs.d/site-lisp")))
+
+(eval-when-compile
+  (require 'org-contacts)
+  (require 'sauron))
+
+(autoload 'identica-mode "identica-mode" nil t)
+(autoload 'mu4e "mu4e" nil t)
+
+(defalias 'yes-or-no-p 'y-or-n-p)
+
+(defmacro oni:define-mailbox (name email &optional signature longname)
+  "Define a mailbox function."
+  `(defun ,(make-symbol (concat "oni:" name "-mailbox")) ()
+     ,(concat "Settings for " name " mailbox")
+     (setq mu4e-mu-home ,(expand-file-name (concat "~/.mu/" name))
+           mu4e-maildir ,(expand-file-name (concat "~/documents/mail/"
+                                                   (or longname name)))
+           mu4e-get-mail-command ,(concat "offlineimap -oa " (or longname
+                                                                 name))
+           mu4e~main-buffer-name ,(concat "*mu4e-" name "*")
+           user-mail-address ,email
+           message-sendmail-extra-arguments '("-a" ,name)
+           message-signature-file ,signature)))
+
+(defmacro oni:generic-outline (regex)
+  "Prepare for enabling `outline-minor-mode'."
+  `(progn
+     (outline-minor-mode)
+     (set (make-local-variable 'outline-regexp) ,regex)
+     (hide-body)
+     (local-set-key [C-tab] 'outline-toggle-children)))
+
+(defun oni:after-save-func ()
+  "Function for `after-save-hook'."
+  (oni:compile-el)
+  (executable-make-buffer-file-executable-if-script-p))
+
+(defun oni:before-save-func ()
+  "Function for `before-save-hook'."
+  (if (eq major-mode 'html-mode)
+      (oni:replace-html-special-chars))
+  (if (not (eq major-mode 'markdown-mode))
+      (delete-trailing-whitespace)))
+
+(defun oni:c-mode-common-func ()
+  "Function for `c-mode-common-hook'."
+  (setq hs-adjust-block-beginning 'hs-c-like-adjust-block-beginning)
+  (hs-minor-mode))
+
+(defun oni:compile-el ()
+  "Compile the current buffer file if it is an .el file."
+  (let* ((full-file-name (buffer-file-name))
+         (file-name (file-name-nondirectory full-file-name))
+         (suffix (file-name-extension file-name)))
+      (if (and (not (string-equal file-name ".dir-locals.el"))
+               (string-equal suffix "el"))
+          (byte-compile-file full-file-name))))
+
+(defun oni:hs-minor-mode-func ()
+  "Function for `hs-minor-mode-hook'."
+  (local-set-key [C-tab] 'hs-toggle-hiding)
+  (hs-hide-all))
+
+(defun oni:jabber-chat-mode-func ()
+  "Function for `jabber-chat-mode-hook'."
+  (visual-line-mode))
+
+(defun oni:mini-fix-timestamp-string (date-string)
+  "A minimal version of Xah Lee's `fix-timestamp-string'
+  function, found at http://xahlee.org/emacs/elisp_parse_time.html"
+  (setq date-string (replace-regexp-in-string "Jan" "01" date-string)
+        date-string (replace-regexp-in-string "Feb" "02" date-string)
+        date-string (replace-regexp-in-string "Mar" "03" date-string)
+        date-string (replace-regexp-in-string "Apr" "04" date-string)
+        date-string (replace-regexp-in-string "May" "05" date-string)
+        date-string (replace-regexp-in-string "Jun" "06" date-string)
+        date-string (replace-regexp-in-string "Jul" "07" date-string)
+        date-string (replace-regexp-in-string "Aug" "08" date-string)
+        date-string (replace-regexp-in-string "Sep" "09" date-string)
+        date-string (replace-regexp-in-string "Oct" "10" date-string)
+        date-string (replace-regexp-in-string "Nov" "11" date-string)
+        date-string (replace-regexp-in-string "Dec" "12" date-string))
+  (string-match
+   "^\\([0-9]\\{2\\}\\)-\\([0-9]\\{2\\}\\)-\\([0-9]\\{4\\}\\)$"
+   date-string)
+  (format "%s-%s-%s"
+          (match-string 3 date-string)
+          (match-string 2 date-string)
+          (match-string 1 date-string)))
+
+(defun oni:myepisodes-formatter (plist)
+  "Format RSS items from MyEpisodes as org tasks."
+  (let ((str (plist-get plist :title)))
+    (string-match
+     "^\\[ \\([^\]]+\\) \\]\\[ \\([^\]]+\\) \\]\\[ \\([^\]]+\\) \\]\\[ \\([^\]]+\\) \\]$"
+     str)
+    (let* ((title (match-string 1 str))
+           (episode (match-string 2 str))
+           (name (match-string 3 str))
+           (date (oni:mini-fix-timestamp-string (match-string 4 str))))
+      (format "* ACQUIRE %s %s - %s <%s>" title episode name date))))
+
+(defun oni:prog-mode-func ()
+  "Function for `prog-mode-hook'."
+  (rainbow-delimiters-mode)
+  (fci-mode)
+  (pretty-symbols-mode))
+
+(defun oni:replace-html-special-chars ()
+  (oni:replace-occurrences "é" "&eacute;"))
+
+(defun oni:replace-occurrences (from to)
+  "Replace all occurrences of FROM with TO in the current buffer."
+  (save-excursion
+    (goto-char (point-min))
+    (while (search-forward from nil t)
+      (replace-match to))))
+
+(defun oni:required-packages-installed-p ()
+  "Check if all the packages I need are installed."
+  (let ((tmp-packages oni:required-packages)
+        (result t))
+    (while (and tmp-packages result)
+      (if (not (package-installed-p (car tmp-packages)))
+          (setq result nil))
+      (setq tmp-packages (cdr tmp-packages)))
+    result))
+
+(defun oni:view-mail ()
+  "Show a menu with all mailbox options from `oni:mailbox-map'
+for easy selection."
+  (interactive)
+  (require 'tmm)
+  (let* ((tmm-completion-prompt "Choose a mailbox\n")
+         (inbox (tmm-prompt oni:mailbox-map)))
+    (if inbox
+        (progn
+          (require 'mu4e)
+          (funcall (intern (concat "oni:" inbox "-mailbox")))
+          (mu4e)))))
+
+(defvar oni:mailbox-map
+  '("top" ("menu"
+           ("ryulash.org" . "ryuslash")
+           ("ninthfloor"  . "ninthfloor")
+           ("gmail"       . "gmail")
+           ("aethon"      . "aethon")))
+  "A mailbox map for use with `tmm-prompt'.")
+
+(defvar oni:required-packages
+  '(graphviz-dot-mode htmlize magit rainbow-delimiters
+                      rainbow-mode yasnippet markdown-mode flymake
+                      flymake-cursor pony-mode sauron dispass
+                      expand-region fill-column-indicator
+                      git-auto-commit-mode idomenu magit smex)
+  "List of all the packages I have (want) installed")
+
+(eval-after-load "mu4e"
+  '(add-to-list
+    'org-capture-templates
+    '("c" "Contact" entry (file "~/documents/org/misc/contacts.org")
+      (concat "* %(mu4e-view-snarf-from 'name)\n"
+              "  :PROPERTIES:\n"
+              "  :EMAIL: %(mu4e-view-snarf-from 'email)\n"
+              "  :END:"))))
+
+(oni:define-mailbox
+ "aethon" "thomas@aethon.nl"
+ (expand-file-name "~/documents/work/aethon/signature.txt"))
+(oni:define-mailbox "gmail" "ryuslash@gmail.com")
+(oni:define-mailbox "ninthfloor" "ryuslash@ninthfloor.org")
+(oni:define-mailbox "ryuslash" "tom@ryuslash.org" nil "ryuslash.org")
+
+(setq-default c-basic-offset 4)
+(setq-default fci-rule-column 73)
+
+(setq fci-rule-color "darkred")
+(setq inferior-lisp-program "sbcl")
+(setq jabber-account-list '(("ryuslash@jabber.org")))
+(setq jabber-chat-buffer-format "*jabber:%n*")
+(setq jabber-chat-buffer-show-avatar nil)
+(setq jabber-chat-fill-long-lines nil)
+(setq jabber-chat-foreign-prompt-format "[%t] < ")
+(setq jabber-chat-local-prompt-format "[%t] > ")
+(setq jabber-chatstates-confirm nil)
+(setq jabber-history-dir "~/.emacs.d/jabber")
+(setq jabber-roster-show-bindings nil)
+(setq jabber-roster-show-offline-contacts nil)
+(setq mail-header-separator "")
+(setq mu4e-headers-date-format "%d-%m %H:%M")
+(setq mu4e-headers-fields '((:date . 11)
+                            (:flags . 6)
+                            (:to . 22)
+                            (:from . 22)
+                            (:subject)))
+(setq mu4e-headers-show-threads nil)
+(setq mu4e-headers-sort-revert nil)
+(setq package-archives
+      '(("melpa" . "http://melpa.milkbox.net/packages/")
+        ("ELPA" . "http://tromey.com/elpa/")
+        ("gnu" . "http://elpa.gnu.org/packages/")
+        ("marmalade" . "http://marmalade-repo.org/packages/")))
+(setq package-load-list '((htmlize "1.39")
+                          all))
+(setq org-feed-alist
+      '(("MyEpisodes"
+         "http://www.myepisodes.com/rss.php?feed=mylist&uid=Slash&pwdmd5=04028968e1f0b7ee678b748a4320ac17"
+         "~/documents/org/org" "MyEpisodes"
+         :formatter oni:myepisodes-formatter)))
+(setq send-mail-function 'smtpmail-send-it)
+(setq sendmail-program "/usr/bin/msmtp")
+(setq yas-prompt-functions '(yas-ido-prompt))
+
+(add-hook 'after-save-hook 'oni:after-save-func)
+(add-hook 'before-save-hook 'oni:before-save-func)
+(add-hook 'c-mode-common-hook 'oni:c-mode-common-func)
+(add-hook 'hs-minor-mode-hook 'oni:hs-minor-mode-func)
+(add-hook 'jabber-chat-mode-hook 'oni:jabber-chat-mode-func)
+(add-hook 'prog-mode-hook 'oni:prog-mode-func)
+
+(global-set-key (kbd "<f6>") 'jabber-switch-to-roster-buffer)
+(global-set-key (kbd "M-n") 'idomenu)
+
+(unless (oni:required-packages-installed-p)
+  (message "%s" "Refreshing package database...")
+  (package-refresh-contents)
+  (message "%s" " done.")
+  (mapc #'(lambda (package)
+            (when (not (package-installed-p package))
+              (package-install package)))
+        oni:required-packages))
+
+(defconst oni:c-outline-regex
+  (eval-when-compile
+    (concat
+     "\\(?:static\\s +\\)?\\(?:\\sw+\\(?: \\|\t\\|\n\\)*?\\*?\\)"
+     "\\(?:\\s \\|\t\\|\n\\)\\(?:\\sw\\|_\\)+([^)]*)[^;\n]*$"))
+  "Regex for `outline-minor-mode' for `c-mode'.")
+
+(defun oni:c-mode-func ()
+  "Function for `c-mode-hook'."
+  (local-set-key [f9] 'compile)
+  (local-set-key "\C-j" 'oni:newline-and-indent))
+
+(add-hook 'c-mode-hook 'oni:c-mode-func)
+
+(defun oni:css-mode-func ()
+  "Function for `css-mode-hook'."
+  (setq hs-adjust-block-beginning 'hs-c-like-adjust-block-beginning)
+  (hs-minor-mode)
+  (local-set-key "\C-j" 'oni:newline-and-indent)
+  (rainbow-mode))
+
+(add-hook 'css-mode-hook 'oni:css-mode-func)
+
+(defun oni:emacs-lisp-mode-func ()
+  "Function for `emacs-lisp-mode-hook'."
+  (eldoc-mode)
+  (when (buffer-file-name)
+    (hs-minor-mode)))
+
+(add-hook 'emacs-lisp-mode-hook 'oni:emacs-lisp-mode-func)
+
+(defun oni:go-mode-func ()
+  "Function for `go-mode-hook'."
+  (setq indent-tabs-mode nil)
+  (local-set-key "\C-j" 'oni:newline-and-indent))
+
+(add-hook 'go-mode-hook 'oni:go-mode-func)
+
+(defun oni:html-mode-func ()
+  "Function for `html-mode-hook'."
+  (fci-mode))
+
+(add-hook 'html-mode-hook 'oni:html-mode-func)
+
+(defconst oni:javascript-outline-regex "function \\(\\w\\|_\\)+("
+  "Regex for `outline-minor-mode' for `js-mode'.")
+
+(defun oni:js-mode-func ()
+  "Function for `js-mode-hook'."
+  (oni:generic-outline oni:javascript-outline-regex)
+  (rainbow-delimiters-mode)
+  (local-set-key "\C-j" 'oni:newline-and-indent))
+
+(add-hook 'js-mode-hook 'oni:js-mode-func)
+
+(add-to-list 'auto-mode-alist '("\\.js\\(on\\)?$" . js-mode))
+
+(defun oni:lisp-mode-func ()
+  "Function for `lisp-mode-hook'."
+  (hs-minor-mode))
+
+(add-hook 'lisp-mode-hook 'oni:lisp-mode-func)
+
+(defconst oni:python-outline-regex
+  (eval-when-compile
+    (concat "^[ \t]*\\(?:@[a-zA-Z0-9_]+\\(?:([a-zA-Z0-9_=, ]*)\\)?"
+            "\n\\)*[ \t]*\\(?:\\(class\\|def\\)[ \t]+\\(\\sw\\|\\s_\\)+"
+            "\\(([^)]*):\\)?\\|\\#[ a-zA-Z0-9]*\\#\\)"))
+  "Regex for `outline-minor-mode' for `python-mode'.")
+
+(defun oni:python-mode-func ()
+  "Function for `python-mode-hook'."
+  (flymake-mode)
+  (local-set-key (kbd "C->") 'python-indent-shift-right)
+  (local-set-key (kbd "C-<") 'python-indent-shift-left)
+  (local-set-key [C-tab] 'outline-toggle-children)
+  (oni:generic-outline oni:python-outline-regex)
+  (set (make-local-variable 'electric-indent-chars) nil)
+  (rainbow-delimiters-mode)
+  (fci-mode))
+
+(add-hook 'python-mode-hook 'oni:python-mode-func)
+
+(autoload 'pony-mode "pony-mode" nil t)
+
+(defconst oni:php-outline-regex
+  (eval-when-compile
+    (concat
+     "^ *\\(\\(?:namespace\\|interface\\) [a-zA-Z0-9_]\\|\\(\\(abstract"
+     "\\|final\\) \\)?class [a-zA-Z0-9_]+\\( extends [\\a-zA-Z0-9_]+\\)?"
+     "\\|\\(abstract \\)?\\(public\\|private\\|protected\\)?"
+     "\\( static\\)? function [a-zA-Z0-9_]+(\\|/\\*\\*\\)"))
+  "Regex for `outline-minor-mode' for `php-mode'.")
+
+(defun oni:php-mode-func ()
+  "Function for `php-mode-hook'."
+  (flymake-mode)
+  ;; (oni:gtags-for-php)
+  (local-set-key "\C-j" 'oni:newline-and-indent)
+  (c-set-offset 'arglist-intro '+)
+  (c-set-offset 'arglist-close '0)
+  (rainbow-delimiters-mode)
+  (setq fci-rule-column 81))
+
+(autoload 'php-mode "php-mode" nil t)
+
+(setq-default php-mode-warn-if-mumamo-off nil)
+
+(setq php-function-call-face 'font-lock-function-name-face
+      php-mode-force-pear t)
+
+(add-to-list 'auto-mode-alist '("\\.php[345]?$" . php-mode))
+
+(add-hook 'php-mode-hook 'oni:php-mode-func)
+
+(add-to-list 'auto-mode-alist '("\\.tpl$" . html-mode))
+
+(defun oni:scheme-mode-func ()
+  "Function for `scheme-mode-hook'."
+  (hs-minor-mode))
+
+(add-hook 'scheme-mode-hook 'oni:scheme-mode-func)
+
+(require 'geiser-install)
+
+(setq geiser-active-implementations '(guile)
+      geiser-repl-history-filename "~/.emacs.d/geiser-history")
+
+(defun oni:java-mode-func ()
+  "Function for `java-mode-hook'."
+  (local-set-key "\C-j" 'oni:newline-and-indent))
+
+(add-hook 'java-mode-hook 'oni:java-mode-func)
+
+(defun oni:close-client-window ()
+  "Close a client's frames."
+  (interactive)
+  (server-save-buffers-kill-terminal nil))
+
+(when (daemonp)
+  (global-set-key "\C-x\C-c" 'oni:close-client-window))
+
+(defun oni:org-mode-func ()
+  "Function for `org-mode-hook'."
+  (flyspell-mode)
+  (auto-fill-mode))
+
+(add-hook 'org-mode-hook 'oni:org-mode-func)
+
+(global-set-key "\C-ca" 'org-agenda)
+(global-set-key "\C-cc" 'org-capture)
+
+(eval-after-load "org"
+  '(progn
+     (require 'appt)
+     (require 'org-protocol)
+     (require 'org-habit)
+     (require 'org-contacts)
+
+     (add-to-list 'org-modules 'habit)
+
+     (org-indent-mode t)
+
+     (org-agenda-to-appt)
+     (ad-activate 'org-agenda-redo)))
+
+(eval-after-load "org-crypt"
+  '(org-crypt-use-before-save-magic))
+
+(setq org-hide-emphasis-markers t)
+
+(setq org-refile-allow-creating-parent-nodes t
+      org-refile-targets '((nil . (:maxlevel . 6)))
+      org-refile-use-outline-path 'file)
+
+(defadvice org-agenda-redo (after org-agenda-redo-add-appts)
+  "Pressing `r' on the agenda will also add appointments."
+  (progn
+    (setq appt-time-msg-list nil)
+    (org-agenda-to-appt)))
+
+(setq org-agenda-custom-commands
+      '(("b" "Bookmarks to look at."
+         todo "LOOKAT")
+        ("w" "Work todo."
+         tags-todo "CATEGORY=\"Work\"")))
+
+(setq org-directory (expand-file-name "~/documents/org"))
+
+(setq org-default-notes-file (concat org-directory "/org"))
+
+(setq org-agenda-files
+      `(,(concat org-directory "/org")
+        ,(concat org-directory "/misc/contacts.org")
+        ,(concat org-directory "/misc/bookmarks.org")))
+
+(setq org-agenda-sorting-strategy       ; How to sort my agenda.
+      '((agenda habit-down time-up priority-down category-keep)
+        (todo priority-down category-up)
+        (tags priority-down category-keep)
+        (search category-keep)))
+
+(setq org-capture-templates             ; What to capture when.
+      '(("t" "Task" entry (file+headline "" "tasks")
+         "* TODO %^{Description}\n  %u\n\n  %?")
+        ("T" "Task with link" entry (file+headline "" "tasks")
+         "* TODO %^{Description}\n  %u\n\n  %a\n  %?")
+        ("h" "Habit" entry (file+headline "" "tasks")
+         (concat "* TODO %^{Description}\n"
+                 "  SCHEDULED: %^T\n"
+                 "  :PROPERTIES:\n"
+                 "  :STYLE:    habit\n"
+                 "  :END:")
+         :immediate-finish t)
+        ("l" "Log" entry (file+headline "" "notes")
+         (concat "* %n %<%d-%m-%Y %H:%M:%S>\n"
+                 "  %a\n\n"
+                 "  %?")
+         :prepend t :empty-lines 1)
+        ("a" "Appointment" entry (file+headline "" "appointments")
+         "* %^{Description} %^T" :immediate-finish t)
+        ("b" "Bookmark" entry (file "~/documents/org/misc/bookmarks.org")
+         "* %c\n\n  %:initial")))
+
+(setq org-export-htmlize-output-type 'css
+      org-outline-path-complete-in-steps t
+      org-return-follows-link t
+      org-src-fontify-natively t
+      org-tags-exclude-from-inheritance '("crypt")
+      org-use-fast-todo-selection t)
+
+(setq org-todo-keyword-faces
+      '(("TODO"        :foreground "red")
+        ("IN PROGRESS" :foreground "yellow")
+        ("DONE"        :foreground "forest green")
+        ("SUCCEEDED"   :foreground "forest green")
+        ("WAITING"     :foreground "orange")
+        ("CANCELLED"   :foreground "orangered")
+        ("FAILED"      :foreground "orangered")))
+
+(setq org-todo-keywords
+      '((sequence "TODO(t)" "IN PROGRESS" "WAITING(@/!)" "|"
+                  "DONE(!/!)" "CANCELLED(@/!)")))
+
+(defun oni:diary-display-func ()
+  "Function for `diary-display-hook'."
+  (diary-fancy-display))
+
+(add-hook 'diary-display-hook 'oni:diary-display-func)
+
+(setq appt-display-diary nil)
+
+(defun oni:newline-and-indent ()
+  (interactive)
+  (if (and (not (or (= (point) (point-max))
+                    (= (point) (point-min))))
+           (or (and (char-equal (char-before) ?{)
+                    (char-equal (char-after) ?}))
+               (and (char-equal (char-before) ?\()
+                    (char-equal (char-after) ?\)))))
+      (save-excursion (newline-and-indent)))
+  (newline-and-indent))
+
+(defun oni:emms-toggle-playing ()
+  "Toggle between playing/paused states."
+  (interactive)
+  (if (eq emms-player-playing-p nil)
+      (emms-start)
+    (emms-pause)))
+
+(eval-after-load "emms-source-file"
+      '(progn
+         (require 'emms-setup)
+
+         (emms-standard)
+         (require 'emms-player-mpd)
+
+         (setq emms-player-mpd-server-name "localhost")
+         (setq emms-player-mpd-server-port "6600")
+
+         (add-to-list 'emms-info-functions 'emms-info-mpd)
+         (add-to-list 'emms-player-list 'emms-player-mpd)
+         (setq emms-player-mpd-music-directory "/mnt/music/mp3")))
+
+(setq emms-source-file-default-directory "/mnt/music/")
+
+(global-set-key [XF86AudioNext] 'emms-next)
+(global-set-key [XF86AudioPlay] 'oni:emms-toggle-playing)
+(global-set-key [XF86AudioPrev] 'emms-previous)
+(global-set-key [XF86AudioStop] 'emms-stop)
+(global-set-key [XF86Tools] 'emms)
+
+(defun oni:erc-mode-func ()
+  "Function for `erc-mode-hook'."
+  (erc-fill-mode -1)
+  (visual-line-mode)
+  (setq truncate-lines nil))
+
+(setq erc-autojoin-channels-alist
+      '(("freenode.net" "#herbstluftwm" "#ninthfloor" "#emacs"
+         "#dispass")))
+
+(setq erc-nick "ryuslash")
+
+(add-hook 'erc-mode-hook 'oni:erc-mode-func)
+
+(setq erc-insert-timestamp-function 'erc-insert-timestamp-left
+      erc-timestamp-format "[%H:%M] "
+      erc-timestamp-only-if-changed-flag nil)
+
+(setq erc-hide-list '("JOIN" "PART" "QUIT"))
+
+(defun oni:eshell-mode-func ()
+  "Function for `eshell-mode-hook'."
+  (setq truncate-lines nil))
+
+(add-hook 'eshell-mode-hook 'oni:eshell-mode-func)
+
+(require 'cl)
+(defun oni:shorten-dir (dir)
+  "Shorten a directory, (almost) like fish does it."
+  (let ((scount (1- (count ?/ dir))))
+    (dotimes (i scount)
+      (string-match "\\(/\\.?.\\)[^/]+" dir)
+      (setq dir (replace-match "\\1" nil nil dir))))
+  dir)
+
+(defun oni:eshell-prompt-function ()
+  (let ((status (if (zerop eshell-last-command-status) ?+ ?-))
+        (hostname (shell-command-to-string "hostname"))
+        (dir (abbreviate-file-name (eshell/pwd)))
+        (branch
+         (shell-command-to-string
+          "git branch --contains HEAD 2>/dev/null | sed -e '/^[^*]/d'"))
+        (userstatus (if (zerop (user-uid)) ?# ?$)))
+    (format "%c%s:%s@%s %c "
+            status
+            (substring hostname 0 -1)
+            (oni:shorten-dir dir)
+            (when (not (string= branch ""))
+              (substring branch 2 -1))
+            userstatus)))
+
+(setq eshell-prompt-function 'oni:eshell-prompt-function)
+
+(defun oni:raise-eshell ()
+  "Start or switch back to `eshell'. Also change directories to
+    current working directory."
+  (interactive)
+  (let ((dir (file-name-directory
+              (or (buffer-file-name) "~/")))
+        (hasfile (not (eq (buffer-file-name) nil))))
+    (eshell)
+    (if (and hasfile (eq eshell-process-list nil))
+        (progn
+          (eshell/cd dir)
+          (eshell-reset)))))
+
+(global-set-key [f8] 'oni:raise-eshell)
+
+(eval-after-load "em-term"
+  '(add-to-list 'eshell-visual-commands
+                "unison"))
+
+(defun oni:flymake-mode-func ()
+  "Function for `flymake-mode-hook'."
+  (local-set-key [M-P] 'flymake-goto-prev-error)
+  (local-set-key [M-N] 'flymake-goto-next-error))
+
+(add-hook 'flymake-mode-hook 'oni:flymake-mode-func)
+
+(defun oni:flymake-pyflakes-init ()
+  "Initialize function for flymake with pyflakes."
+  (let* ((temp-file (flymake-init-create-temp-buffer-copy
+                     'flymake-create-temp-inplace))
+         (local-file (file-relative-name temp-file (file-name-directory
+                                                    buffer-file-name))))
+    (list "pyflakes" (list local-file))))
+
+(eval-after-load "flymake"
+  '(progn
+     (require 'flymake-cursor)
+
+     (add-to-list                       ; Make sure pyflakes is loaded
+      'flymake-allowed-file-name-masks  ; for python files.
+      '("\\.py\\'" oni:flymake-pyflakes-init))
+
+     (add-to-list                       ; Error line repexp for go
+      'flymake-err-line-patterns        ; compilation.
+      '("^\\([a-zA-Z0-9_]+\\.go\\):\\([0-9]+\\):\\(.*\\)$"
+        1 2 nil 3))
+
+     (add-to-list                       ; Go uses makefiles, makes
+      'flymake-allowed-file-name-masks  ; flymaking 'easy'.
+      '("\\.go$" flymake-simple-make-init))))
+
+(setq flymake-log-file-name (expand-file-name "~/.emacs.d/flymake.log")
+      flymake-log-level 0
+      flymake-gui-warnings-enabled nil)
+
+(autoload 'gtags-mode "gtags" nil t)
+
+(defun oni:gtags-create-or-update ()
+  "Create or update the GNU Global tag file"
+  (interactive)
+  (if (not (= 0 (call-process "global" nil nil nil " -p")))
+      (let ((olddir default-directory)
+            (topdir (read-directory-name
+                     "gtags: top of source tree:" default-directory)))
+        (cd topdir)
+        (shell-command "~/bin/create_gtags")
+        (cd olddir))
+    ;; Tagfile already exists; update it
+    (shell-command "~/bin/update_gtags")))
+
+(defun oni:gtags-for-php ()
+  "Setup gtags for `php-mode'."
+  (let* ((file-name (buffer-file-name))
+         (fext (if (not (eq nil file-name))
+                   (file-name-extension (buffer-file-name))
+                 nil)))
+    (if (equal fext "php")
+        (progn
+          (gtags-mode)
+          (oni:gtags-create-or-update)))))
+
+(defun oni:gtags-mode-func ()
+  "Function for `gtags-mode-hook'."
+  (local-set-key "\M-," 'gtags-find-tag)
+  (local-set-key "\M-." 'gtags-find-rtag))
+
+(add-hook 'gtags-mode-hook 'oni:gtags-mode-func)
+
+(setq gtags-auto-update t)
+
+(require 'newcomment)
+
+(defun oni:kill-region-or-backward-char ()
+  "Kill either the active region, or delete the character left of
+  the cursor"
+  (interactive)
+  (if (region-active-p)
+      (kill-region (region-beginning) (region-end))
+    (backward-delete-char-untabify 1)))
+
+(global-set-key "\C-w" 'oni:kill-region-or-backward-char)
+
+(defun oni:kill-region-or-forward-char ()
+  "Kill either the active region, or delete the character right
+  of the cursor"
+  (interactive)
+  (if (region-active-p)
+      (kill-region (region-beginning) (region-end))
+    (delete-forward-char 1)))
+
+(global-set-key "\C-d" 'oni:kill-region-or-forward-char)
+
+(defun oni:kill-region-or-line ()
+  "Kill either the active region, or the rest of the line,
+  depending on whether or not `region-active-p' is t"
+  (interactive)
+  (if (region-active-p)
+      (kill-region (region-beginning) (region-end))
+    (kill-line)))
+
+(global-set-key "\C-k" 'oni:kill-region-or-line)
+
+(defun oni:move-beginning-of-dwim ()
+  "Move to the beginning of line, either after the indentatoin of
+  before."
+  (interactive)
+  (let ((start (point)))
+    (back-to-indentation)
+    (if (= start (point))
+        (beginning-of-line))))
+
+(global-set-key "\C-a" 'oni:move-beginning-of-dwim)
+
+(defun oni:move-end-of-dwim ()
+  "Move to the end of line, either before any comments or after
+  them."
+  (interactive)
+  (let ((start (point))
+        (eolpos (line-end-position)))
+    (beginning-of-line)
+    (if (and comment-start
+             (comment-search-forward eolpos t))
+        (progn
+          (search-backward-regexp (concat "[^ \t" comment-start "]"))
+          (forward-char)
+
+          (when (or (bolp)
+                    (= start (point)))
+            (end-of-line)))
+      (end-of-line))))
+
+(global-set-key "\C-e" 'oni:move-end-of-dwim)
+
+(defun oni:self-insert-dwim ()
+  "Execute self insert, but when the region is active call self
+  insert at the end of the region and at the beginning."
+  (interactive)
+  (if (region-active-p)
+      (let ((electric-pair-mode nil)
+            (beginning (region-beginning))
+            (end (region-end)))
+        (goto-char end)
+        (self-insert-command 1)
+        (save-excursion
+          (goto-char beginning)
+          (self-insert-command 1)))
+    (self-insert-command 1)))
+
+(global-set-key "'" 'oni:self-insert-dwim)
+(global-set-key "\"" 'oni:self-insert-dwim)
+
+(global-set-key [f7] 'magit-status)
+
+(defun oni:magit-log-edit-mode-func ()
+  "Function for `magit-log-edit-mode-hook'."
+  (auto-fill-mode)
+  (font-lock-add-keywords
+   nil
+   '(("\\`\\(.\\{,50\\}\\)\\(.*\\)\n?\\(.*\\)$"
+      (1 'git-commit-summary-face)
+      (2 'git-commit-overlong-summary-face)
+      (3 'git-commit-nonempty-second-line-face))
+     ("`\\([^']+\\)'" 1 font-lock-constant-face))
+   t))
+
+(add-hook 'magit-log-edit-mode-hook 'oni:magit-log-edit-mode-func)
+
+(defun oni:markdown-mode-func ()
+  "Function for `markdown-mode-hook'."
+  (auto-fill-mode)
+  (whitespace-mode))
+
+(add-hook 'markdown-mode-hook 'oni:markdown-mode-func)
+
+(add-to-list 'auto-mode-alist '("\\.m\\(ark\\)?do?wn$" . markdown-mode))
+
+(setq whitespace-style '(face trailing))
+
+(defun oni:message-mode-func ()
+  "Function for `message-mode-hook'."
+  (auto-fill-mode)
+  (flyspell-mode)
+  (ispell-change-dictionary (read-string "New dictionary: ")))
+
+(setq message-send-mail-function 'message-send-mail-with-sendmail)
+
+(add-hook 'message-mode-hook 'oni:message-mode-func)
+
+(require 'w3m-load)
+
+(require 'uniquify)
+
+(setq uniquify-buffer-name-style 'post-forward)
+
+(defun oni:raise-scratch (&optional mode)
+  "Show the *scratch* buffer. If called with a universal
+argument, ask the user which mode to use. If MODE is not nil,
+open a new buffer with the name *MODE-scratch* and load MODE as
+its major mode."
+  (interactive (list (if current-prefix-arg
+                         (read-string "Mode: ")
+                       nil)))
+  (let* ((bname (if mode
+                    (concat "*" mode "-scratch*")
+                  "*scratch*"))
+         (buffer (get-buffer bname))
+         (mode-sym (intern (concat mode "-mode"))))
+
+    (unless buffer
+      (setq buffer (generate-new-buffer bname))
+      (with-current-buffer buffer
+        (when (fboundp mode-sym)
+          (funcall mode-sym))))
+
+    (switch-to-buffer buffer)))
+
+(setq initial-major-mode 'emacs-lisp-mode
+      initial-scratch-message nil)
+
+(global-set-key [XF86HomePage] 'oni:raise-scratch)
+
+(defun oni:reload-buffer ()
+  "Reload current buffer."
+  (interactive)
+  (revert-buffer nil t nil))
+
+(global-set-key [f5] 'oni:reload-buffer)
+
+(defun oni:term-mode-func ()
+  "Function for `term-mode-hook'."
+  (setq truncate-lines nil))
+
+(add-hook 'term-mode-hook 'oni:term-mode-func)
+
+(defun oni:texinfo-mode-func ()
+  "Function for `texinfo-mode-hook'."
+  (auto-fill-mode))
+
+(add-hook 'texinfo-mode-hook 'oni:texinfo-mode-func)
+
+(autoload 'xmodmap-mode "xmodmap-mode" nil t)
+(add-to-list 'auto-mode-alist '("^\\.Xmodmap$" . xmodmap-mode))
+
+(defun oni:indent-shift-left (start end &optional count)
+  (interactive
+   (if mark-active
+       (list (region-beginning) (region-end) current-prefix-arg)
+     (list (line-beginning-position)
+           (line-end-position)
+           current-prefix-arg)))
+  (if count
+      (setq count (prefix-numeric-value count))
+    (setq count tab-width))
+  (when (> count 0)
+    (let ((deactivate-mark nil))
+      (save-excursion
+        (goto-char start)
+        (while (< (point) end)
+          (if (and (< (current-indentation) count)
+                   (not (looking-at "[ \t]*$")))
+              (error "Can't shift all lines enough"))
+          (forward-line))
+        (indent-rigidly start end (- count))))))
+
+(add-to-list 'debug-ignored-errors "^Can't shift all lines enough")
+
+(defun oni:indent-shift-right (start end &optional count)
+  (interactive
+   (if mark-active
+       (list (region-beginning) (region-end) current-prefix-arg)
+     (list (line-beginning-position)
+           (line-end-position)
+           current-prefix-arg)))
+  (let ((deactivate-mark nil))
+    (if count
+        (setq count (prefix-numeric-value count))
+      (setq count tab-width))
+    (indent-rigidly start end count)))
+
+(global-set-key (kbd "C-<") 'indent-shift-left)
+(global-set-key (kbd "C->") 'indent-shift-right)
+
+(autoload 'po-mode "po-mode" nil t)
+(add-to-list 'auto-mode-alist '("\\.po\\'\\|\\.po\\." . po-mode))
+
+(autoload 'sawfish-mode "sawfish" nil t)
+
+(add-to-list 'auto-mode-alist '("\\.jl$" . sawfish-mode))
+
+(electric-indent-mode)
+(electric-pair-mode)
+(show-paren-mode)
+(savehist-mode)
+
+(blink-cursor-mode -1)
+(menu-bar-mode -1)
+(scroll-bar-mode -1)
+(tool-bar-mode -1)
+(tooltip-mode -1)
+
+(defun oni:write-file-func ()
+  "Function for `write-file-hooks'."
+  (time-stamp))
+
+(add-hook 'write-file-hooks 'oni:write-file-func)
+
+(setq time-stamp-active t)
+(setq time-stamp-format "%04y-%02m-%02d %02H:%02M:%02S (%u)")
+
+(ido-mode)
+
+(setq ido-auto-merge-delay-time 1000000)
+
+(setq ido-save-directory-list-file nil)
+
+(eval-after-load "ido"
+  '(setq ido-ignore-buffers `(,@ido-ignore-buffers
+                              "^\\*.*\\*$" "^irc\\." "^\\#")))
+
+(setq smex-save-file "~/.emacs.d/smex-items")
+
+(smex-initialize)
+
+(eval-after-load "smex"
+  '(progn
+     (global-set-key (kbd "M-x") 'smex)
+     (global-set-key (kbd "C-M-x") 'smex-major-mode-commands)))
+
+(require 'iso-transl)
+
+(setq-default bidi-paragraph-direction 'left-to-right)
+
+(setq-default gac-automatically-push-p t)
+
+(setq-default indent-tabs-mode nil
+              tab-width 4)
+
+(setq-default require-final-newline t)
+
+(setq-default truncate-lines t)
+
+(add-to-list 'auto-mode-alist '("^PKGBUILD$" . shell-script-mode))
+
+(setq auto-mode-case-fold nil)
+
+(setq auto-save-file-name-transforms
+      `((".*" ,temporary-file-directory t))
+
+      backup-directory-alist
+      `((".*" . ,temporary-file-directory)))
+
+(setq browse-url-browser-function 'browse-url-generic
+      browse-url-generic-program (getenv "BROWSER"))
+
+(setq custom-file "~/.emacs.d/custom.el")
+
+(setq custom-theme-directory "~/.emacs.d/themes")
+(add-to-list 'custom-theme-load-path
+             (concat custom-theme-directory "/naquadah-theme"))
+(load-theme 'naquadah t)
+
+(setq
+ default-frame-alist
+ `((border-width . 0)
+   (internal-border-width . 0)
+   (vertical-scroll-bars . nil)
+   (menu-bar-lines . nil)
+   (tool-bar-lines . nil)
+   (font . "DejaVu Sans Mono:pixelsize=18")
+   (left-fringe . 0)))
+
+(setq frame-title-format '(:eval (concat "emacs: " (buffer-name))))
+
+(setq help-at-pt-display-when-idle t)
+(help-at-pt-set-timer)
+
+(setq sauron-max-line-length 189)
+
+(eval-after-load "sauron"
+  '(setq sauron-modules (append '(sauron-identica sauron-jabber)
+                                sauron-modules)))
+
+  (setq sauron-column-alist               ; I don't need as much
+        '((timestamp . 6)                 ; information as the default.
+          (message)))
+
+(setq sauron-hide-mode-line t)
+(setq sauron-timestamp-format "%H:%M")
+(setq sauron-watch-nicks '("ryuslash"))
+(setq sauron-watch-patterns '("ryuslash"))
+(setq special-display-buffer-names '("*Sauron*"))
+(setq special-display-frame-alist
+      '((minibuffer . nil)
+        (right-fringe . 0)))
+
+(setq inhibit-default-init t)
+
+(setq inhibit-local-menu-bar-menus t)
+
+(setq inhibit-startup-message t)
+
+(setq jit-lock-defer-time 0.2)
+
+(setq message-log-max 1000)
+
+(setq org-blog-directory "~/code/projects/orgweb/blog"
+      org-blog-unfinished-directory "~/documents/blog/drafts")
+
+(setq org-contacts-files '("~/documents/org/misc/contacts.org"))
+
+(setq rainbow-delimiters-max-face-count 12)
+
+(setq redisplay-dont-pause t)
+
+(put 'upcase-region 'disabled nil)
+(put 'downcase-region 'disabled nil)
+(put 'narrow-to-region 'disabled nil)
+
+(global-set-key (kbd "C-@") 'er/expand-region)
+
+(defface oni:mode-line-modified
+  '((t (:inherit font-lock-warning-face)))
+  "Face for the modified state in the mode-line"
+  :group 'local)
+
+(defface oni:mode-line-mode
+  '((t (:inherit font-lock-string-face)))
+  "Face for the major mode in the mode-line"
+  :group 'local)
+
+(defface oni:mode-line-buffer-position
+  '((t (:inherit font-lock-constant-face)))
+  "Face for the buffer position in the mode-line"
+  :group 'local)
+
+(defface oni:mode-line-buffer-line
+  '((t (:inherit font-lock-type-face)))
+  "Face for the line number in the mode-line"
+  :group 'local)
+
+(defface oni:mode-line-buffer-column
+  '((t (:inherit font-lock-type-face)))
+  "Face for the column number in the mode-line"
+  :group 'local)
+
+(defface oni:mode-line-buffer-state
+  '((t (:inherit font-lock-preprocessor-face)))
+  "Face for the state of the buffer in the mode-line"
+  :group 'local)
+
+(setq-default
+ mode-line-format
+ (list
+  '(:eval (if (and (buffer-modified-p) (buffer-file-name))
+              (propertize "!"
+                          'face 'oni:mode-line-modified
+                          'help-echo "Buffer has been modified")
+            " "))
+
+  '(:eval (propertize "%m"
+                      'face 'oni:mode-line-mode
+                      'help-echo buffer-file-coding-system))
+
+  ": "
+
+  '(:eval (propertize "%b "
+                      'face 'mode-line-buffer-id
+                      'help-echo (buffer-file-name)))
+
+  "("
+  (propertize "%p" 'face 'oni:mode-line-buffer-position) ":"
+  (propertize "%04l" 'face 'oni:mode-line-buffer-line) ","
+  (propertize "%02c" 'face 'oni:mode-line-buffer-column)
+  ") "
+
+  "["
+  '(:eval (propertize
+           (if buffer-read-only
+               "R"
+             (if overwrite-mode "O" "I"))
+           'face 'oni:mode-line-buffer-state
+           'help-echo (concat "Buffer is "
+                              (if buffer-read-only
+                                  "read-only"
+                                (if overwrite-mode
+                                    "in overwrite mode"
+                                  "in insert mode")))))
+
+  "] "
+
+  '(:eval (propertize (format-time-string "%H:%M")
+                      'help-echo
+                      (concat (format-time-string "%c; ")
+                              (emacs-uptime "Uptime: %hh"))))
+  " --"
+  '(:eval global-mode-string)))
+
+(setq scroll-conservatively 101)
+
+(setq use-dialog-box nil)
+
+(setq user-full-name "Tom Willemsen")
+
+(define-key key-translation-map (kbd "C-j") (kbd "C-l"))
+(define-key key-translation-map (kbd "C-l") (kbd "C-j"))
+
+(global-set-key "\C-x\C-b" 'electric-buffer-list)
+(global-set-key "\C-\M-d" 'kill-word)
+(global-set-key "\C-\M-w" 'backward-kill-word)
+(global-set-key (kbd "C-S-k") 'kill-whole-line)
+(global-set-key [XF86Mail] 'oni:view-mail)
+(global-set-key "\C-cip" 'identica-update-status-interactive)
+
+(when (or window-system (daemonp))
+  (global-unset-key "\C-z"))
+
+(load custom-file)
+(load "rudel-loaddefs.el")
+(load (expand-file-name "~/quicklisp/slime-helper.el"))