;;; convert.scm -- Convert the old database into a new one
(declare (uses paths))

(require-extension sqlite3)
(require-library srfi-4)

(define (blob->seconds blob)
  (u32vector-ref (blob->u32vector blob) 0))

(define (convert-table db name converter #!optional select)
  (let ((count (first-result db (string-append "SELECT COUNT(*) FROM " name)))
        (progress 0))
    (for-each-row (lambda args
                    (apply converter args)
                    (set! progress (+ progress 1))
                    (format #t "Converted ~s of ~s ~a rows\r~!" progress count name))
                  db (or select (string-append "SELECT * FROM " name)))
    (newline)))

(define (convert)
  (let ((old-db (open-database (data-file "linkwave.db")))
        (new-db (open-database (data-file "nlinkwave.db"))))
    (execute new-db "CREATE TABLE bookmark (url VARCHAR(255) UNIQUE, date INTEGER, name VARCHAR(255), description TEXT)")
    (execute new-db "CREATE TABLE tag (name VARCHAR(255) UNIQUE)")
    (execute new-db "CREATE TABLE bookmark_tag (bookmark_id INTEGER REFERENCES bookmark(rowid), tag_id INTEGER REFERENCES tag(rowid), PRIMARY KEY (bookmark_id, tag_id))")

    (convert-table old-db "bookmark"
                   (lambda (url dateblob name description)
                     (execute new-db "INSERT INTO bookmark VALUES (?, ?, ?, ?)"
                              url (blob->seconds dateblob) name description)))

    (convert-table old-db "tag"
                   (lambda (name)
                     (execute new-db "INSERT INTO tag VALUES (?)" name)))

    (convert-table old-db "bookmark_tag"
                   (lambda (url tag)
                     (execute new-db "INSERT INTO bookmark_tag VALUES (?, ?)"
                              (first-result new-db "SELECT rowid FROM bookmark WHERE url = ?" url)
                              (first-result new-db "SELECT rowid FROM tag WHERE name = ?" tag)))
                   "SELECT url, name FROM bookmark_tag JOIN tag ON (tag_id = tag.rowid)")

    (rename-file (data-file "linkwave.db") (data-file "old-linkwave.db"))
    (rename-file (data-file "nlinkwave.db") (data-file "linkwave.db"))
    (format #t "Database converted.~%")))

(if (file-exists? "/home/slash/.local/share/linkwave/nlinkwave.db")
    (format #t "Converted database already exists.~%")
    (convert))