;;; oni-php.el --- PHP Configuration -*- lexical-binding: t; -*-
;; Copyright (C) 2019 Tom Willemse
;; Author: Tom Willemse <tom@ryuslash.org>
;; Keywords: local
;; Version: 2025.0210.125238
;; Package-Requires: (php-mode oni-yasnippet oni-flycheck oni-company oni-hydra ggtags fic-mode company-php)
;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <https://www.gnu.org/licenses/>.
;;; Commentary:
;; My PHP mode configuration. Includes rules for aligning variables according to
;; the WordPress coding standards.
;;; Code:
(require 'align)
(require 'company)
(require 'hydra)
(require 'php-mode)
(require 'whitespace)
(require 'yasnippet)
(defconst oni-php-root
(file-name-directory
(or load-file-name
(buffer-file-name)))
"The directory where ‘oni-php’ was loaded from.")
(defconst oni-php-snippets-dir
(expand-file-name "snippets" oni-php-root)
"The directory where ‘oni-php’ stores its snippets.")
(defconst oni-php-scripts-dir
(expand-file-name "scripts" oni-php-root)
"The directory where ‘oni-php’ stores its scripts.")
(defun oni-php-snippets-initialize ()
"Initialize the snippets for ‘oni-php’."
(when (boundp 'yas-snippet-dirs)
(add-to-list 'yas-snippet-dirs oni-php-snippets-dir))
(yas-load-directory oni-php-snippets-dir))
(defun oni-php--set-require-final-newline ()
"Set `require-final-newline' to t.
This is necessary because the PHP mode configuration sets this to
nil for some reason."
(setq require-final-newline t))
(defun oni-php--whitespace-mode ()
"Enable whitespace mode with only tabs showing."
(setq-local whitespace-style '(face tabs))
(whitespace-mode))
(defun oni-php--auto-fill-mode ()
"Enable ‘auto-fill-mode’ only for comments."
(setq-local comment-auto-fill-only-comments t)
(auto-fill-mode))
(defun oni-php-add-use (class)
"Try to add a use statement for CLASS under point."
(interactive (list (symbol-name (symbol-at-point))))
(let* ((default-directory (project-root (project-current)))
(classes (read (shell-command-to-string (concat (expand-file-name "find-php-class" oni-php-scripts-dir) " " class))))
(class (cond
((null classes)
(user-error "Class ‘%s’ not found" class))
((> (length classes) 1)
(completing-read "Use: " classes nil t))
(t (car classes)))))
(save-excursion
(goto-char (point-min))
(if (search-forward "use " nil t)
(forward-paragraph)
(search-forward "namespace ")
(forward-line)
(insert "\n"))
(let ((start (point)))
(insert "use " class ";\n")
(pulse-momentary-highlight-region start (point))))))
(defun oni-php-insert-dot-dwim (N)
"Insert either a concatenation or access operator depending on context.
Do the insert N times."
(interactive "p")
(if (or (let ((syntax (syntax-ppss)))
(or (nth 3 syntax)
(nth 4 syntax)))
(save-excursion
(skip-syntax-backward " ")
(nth 3 (syntax-ppss (1- (point)))))
(save-excursion
(skip-syntax-forward " ")
(nth 3 (syntax-ppss (1+ (point))))))
(self-insert-command N)
(dotimes (_ N) (insert "->"))))
(defun oni-php-doc-comment ()
"Insert a PHP documentation comment at point."
(interactive)
(let ((start (point)))
(insert "/**\n * ")
(let ((insert-marker (point-marker)))
(insert "\n */")
(indent-region start (point))
(goto-char insert-marker))))
(defun oni-php-comment-dwim (func &rest args)
"See if a PHP documentation comment should be added and add it.
Otherwise call FUNC with ARGS. This is meant as advice around
‘comment-dwim’ to make it smarter for PHP code."
(if (and (derived-mode-p 'php-mode)
(looking-back (rx blank) (line-beginning-position))
(looking-at (rx (minimal-match (zero-or-more (any whitespace "\n")))
(regexp php-beginning-of-defun-regexp))))
(oni-php-doc-comment)
(apply func args)))
(defhydra php-mode-hydra (:color blue)
("a" align-current "Align current selection"))
(advice-add 'comment-dwim :around #'oni-php-comment-dwim)
(add-hook 'php-mode-hook #'oni-php--set-require-final-newline)
(add-hook 'php-mode-hook #'oni-php--whitespace-mode)
(add-hook 'php-mode-hook 'company-mode)
(add-hook 'php-mode-hook 'display-fill-column-indicator-mode)
(add-hook 'php-mode-hook 'electric-indent-local-mode)
(add-hook 'php-mode-hook 'electric-pair-local-mode)
(add-hook 'php-mode-hook 'fic-mode)
(add-hook 'php-mode-hook 'flycheck-mode)
(add-hook 'php-mode-hook 'ggtags-mode)
(add-hook 'php-mode-hook 'oni-php--auto-fill-mode)
(add-hook 'php-mode-hook 'yas-minor-mode)
(add-hook 'php-mode-hook 'subword-mode)
(with-eval-after-load 'company
(add-to-list 'company-backends 'company-ac-php-backend))
(define-key php-mode-map (kbd "C-c m") #'php-mode-hydra/body)
(define-key php-mode-map (kbd ".") #'oni-php-insert-dot-dwim)
;; In PHP code it's nice to have any ~=>~ aligned.
;; <?php
;; array(
;; 'foo' => 'bar',
;; 'frob' => 'baz'
;; );
;; ?>
(add-to-list 'align-rules-list
`(php-array-arrow
(regexp . ,(rx any (group (zero-or-more whitespace)) "=>" any))
(group . (1))
(modes . '(php-mode web-mode))
(repeat . t)))
;; The WordPress coding standards specify that multiple assignments
;; should have their assignment operators aligned.
;; <?php
;; $variable = "value";
;; $other_variable = "other value";
;; $one_more_variable = "one more variable";
(add-to-list 'align-rules-list
`(php-assignment-equals
(regexp . ,(rx any (group (zero-or-more whitespace)) "="
(zero-or-more whitespace) any))
(group . (1))
(modes . '(php-mode web-mode))
(repeat . t)))
(with-eval-after-load 'php-mode
(with-eval-after-load 'yasnippet
(oni-php-snippets-initialize)))
;;;###autoload
(add-to-list 'auto-mode-alist '("\\.inc\\'" . php-mode))
;;;###autoload
(add-to-list 'auto-mode-alist '("\\.module\\'" . php-mode))
;;;###autoload
(with-eval-after-load 'grep
(add-to-list 'grep-files-aliases '("php" . "*.php *.inc *.module")))
(provide 'oni-php)
;;; oni-php.el ends here