(define-module (oni home services emacs)
  #:use-module ((gnu services configuration)
                #:select (serialize-package
                          define-configuration
                          define-configuration/no-serialization
                          text-config?
                          serialize-text-config))
  #:use-module ((gnu packages emacs)
                #:select (emacs))
  #:use-module ((gnu packages emacs-xyz)
                #:select (emacs-helpful))
  #:use-module ((gnu home services)
                #:select (service-type
                          service-extension
                          home-profile-service-type
                          home-files-service-type))
  #:use-module ((gnu home services shepherd)
                #:select (shepherd-service
                          home-shepherd-service-type))
  #:use-module ((guix gexp)
                #:select (gexp
                          file-append
                          local-file
                          mixed-text-file))
  #:use-module ((guix packages)
                #:select (package?))

  #:use-module ((oni packages emacs)
                #:select (emacs-yasnippet-capf))

  #:export (home-emacs-service-type
            home-emacs-configuration

            home-emacs-helpful-service-type
            home-emacs-helpful-configuration

            home-emacs-yasnippet-capf-service-type
            home-emacs-yasnippet-capf-configuration))

(define-configuration/no-serialization home-emacs-extension
  (configurations
   (text-config '())
   "The configuration for the extension."))

(define-configuration home-emacs-configuration
  (package
    (package emacs)
    "Package to use for setting Emacs")
  (configurations
   (text-config '())
   "A list of other configuration files to autoload"))

(define (add-emacs-packages config)
  (list (home-emacs-configuration-package config)))

(define (home-emacs-extensions original-config extension-configs)
  (home-emacs-configuration
   (inherit original-config)
   (configurations
    (apply append (home-emacs-configuration-configurations original-config)
           (map home-emacs-extension-configurations extension-configs)))))

(define (home-emacs-shepherd-service config)
  (list
   (shepherd-service
    (documentation "Start Emacs")
    (provision '(emacs))
    (auto-start? #t)
    (start
     #~(make-forkexec-constructor
        (list #$(file-append (home-emacs-configuration-package config) "/bin/emacs")
              "--fg-daemon")
        #:log-file (format #f "~a/.local/var/log/xbindkeys.log" (getenv "HOME"))))
    (stop #~(make-kill-destructor)))))

(define (home-emacs-config-files config)
  `((".emacs.d/init.el"
     ,(mixed-text-file
       "init.el"
       (serialize-text-config config (home-emacs-configuration-configurations config))))))

(define home-emacs-service-type
  (service-type
   (name 'home-emacs)
   (extensions
    (list (service-extension
           home-profile-service-type
           add-emacs-packages)
          (service-extension
           home-shepherd-service-type
           home-emacs-shepherd-service)
          (service-extension
           home-files-service-type
           home-emacs-config-files)))
   (compose identity)
   (extend home-emacs-extensions)
   (default-value (home-emacs-configuration))
   (description "Install and configure Emacs.")))

(define-configuration/no-serialization home-emacs-helpful-configuration
  (package
    (package emacs-helpful)
    "Package to use for setting emacs-helpful.")
  (configurations
   (text-config '())
   "Configuration for emacs-helpful."))

(define (add-emacs-helpful config)
  (home-emacs-extension
   (configurations (home-emacs-helpful-configuration-configurations config))))

(define (add-emacs-helpful-packages config)
  (list (home-emacs-helpful-configuration-package config)))

(define home-emacs-helpful-service-type
  (service-type
   (name 'home-emacs-helpful)
   (extensions
    (list (service-extension
           home-emacs-service-type
           add-emacs-helpful)
          (service-extension
           home-profile-service-type
           add-emacs-helpful-packages)))
   (compose identity)
   (default-value (home-emacs-helpful-configuration))
   (description "Install and configure emacs-helpful.")))

(define-configuration/no-serialization home-emacs-yasnippet-capf-configuration
  (package
    (package emacs-yasnippet-capf)
    "Package to use for setting emacs-yasnippet-capf.")
  (configurations
   (text-config '())
   "Configuration for emacs-yasnippet-capf."))

(define (add-emacs-yasnippet-capf config)
  (home-emacs-extension
   (configurations
    (append
     (list (mixed-text-file "yasnippet-capf-config"
                            "(with-eval-after-load 'minibuffer (add-to-list 'completions-at-point-functions #'yasnippet-capf))\n"))
     (home-emacs-yasnippet-capf-configuration-configurations config)))))

(define (add-emacs-yasnippet-capf-packages config)
  (list (home-emacs-yasnippet-capf-configuration-package config)))

(define home-emacs-yasnippet-capf-service-type
  (service-type
   (name 'home-yasnippet-capf)
   (extensions
    (list (service-extension
           home-emacs-service-type
           add-emacs-yasnippet-capf)
          (service-extension
           home-profile-service-type
           add-emacs-yasnippet-capf-packages)))
   (compose identity)
   (default-value (home-emacs-yasnippet-capf-configuration))
   (description "Install and configure emacs-yasnippet-capf.")))