dotfiles/emacs/.emacs.d/init/oni-org-init.el

;;; oni-org-init.el --- Org-mode configuration       -*- lexical-binding: t; -*-

;; Copyright (C) 2018  Tom Willemse

;; Author: Tom Willemse <tom@ryuslash.org>
;; Keywords: local

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; My configuration for org-mode. I try to implement a GTD workflow.

;;; Code:

(require 'org)
(require 'org-bullets)
(require 'org-capture)
(require 'org-habit)

(defun oni-org-init-setup-prettify-symbols-mode ()
  "Set up prettify symbols mode for org mode."
  (when (member "Ionicons" (font-family-list))
    (setq-local prettify-symbols-alist
                '(("[ ]" . #xf372)
                  ("[X]" . #xf374)))
    (set-face-attribute 'org-checkbox nil :family "Ionicons")
    (prettify-symbols-mode)))

(defun oni-org-init-heading-has-predecessor-p ()
  "Determine if the heading at point has any predecessors.
Only tasks of a level greater than 3 are considered. A task has a
predecessor if there is a non-DONE sibling defined before it."
  (let ((point (point)))
    (save-excursion
      (org-backward-heading-same-level 1)
      (seq-let [level _ keyword] (org-heading-components)
        (not (or (< level 3)
                 (= point (point))
                 (member keyword org-done-keywords)))))))

(defun oni-org-init-looking-for-tag-p (tag)
  "Return t if we're currently looking for TAG in an agenda."
  (and (eql 'org-tags-view (car org-agenda-redo-command))
       (string-match-p (rx-to-string `(and word-start ,tag word-end))
                       org-agenda-query-string)))

(defun oni-org-init-next-heading-position ()
  "Get the position of the next Org heading."
  (or (ignore-errors
        (org-forward-element)
        (point))
      (point-max)))

(defun oni-org-init-skip-tasks ()
  "Skip over tasks I don't want to see right now.
Tasks being skipped over include ones with the \"ex\" tag and
ones that have a predecessor."
  (let ((tags (org-get-tags-at (point))))
    (when (or (and (not (oni-org-init-looking-for-tag-p "ex"))
                   (member "ex" tags))
              (oni-org-init-heading-has-predecessor-p))
      (oni-org-init-next-heading-position))))

(setq org-default-notes-file "~/documents/gtd/inbox.org")
(setq org-src-fontify-natively t)
(setq org-return-follows-link t)
(setq org-fontify-whole-heading-line t)
(setq org-hide-emphasis-markers t)
(setq org-return-follows-link t)
(setq org-use-fast-todo-selection t)
(setq org-log-into-drawer t)
(setq org-agenda-todo-ignore-scheduled 'future)
(setq org-agenda-skip-function-global #'oni-org-init-skip-tasks)

(setq org-agenda-files
      '("~/documents/gtd/todo.org"
        "~/documents/gtd/projects.org"
        "~/documents/gtd/appointments.org"))

(setq org-refile-targets
      '(("~/documents/gtd/todo.org" :maxlevel . 1)
        ("~/documents/gtd/projects.org" :level . 2)
        ("~/documents/gtd/someday.org" :maxlevel . 2)
        ("~/documents/gtd/appointments.org" :maxlevel . 1)))

(setq org-capture-templates
      '(("t" "Note" entry (file "~/documents/gtd/inbox.org")
         "* TODO %i%?")
        ("a" "Appointment" entry (file "~/documents/gtd/appointments.org")
         "* %i%?\n  %U")))

(setq org-todo-keywords
      '((sequence "TODO(t)" "BLOCKED(b@)" "PROGRESS(p)"
                  "|" "DONE(d!)" "CANCELLED(c@)")))

(add-to-list 'org-modules 'org-habit)

(add-hook 'org-mode-hook 'auto-fill-mode)
(add-hook 'org-mode-hook 'org-bullets-mode)
(add-hook 'org-mode-hook #'oni-org-init-setup-prettify-symbols-mode)

(provide 'oni-org-init)
;;; oni-org-init.el ends here