# Maintainer: Tom Willemse <tom@ryuslash.org>

pkgname=cl-sqlite
pkgver=0.2
pkgrel=1
pkgdesc="A library for interacting with sqlite databases through SQL."
arch=('x86_64')
url="http://common-lisp.net/project/cl-sqlite/"
license=('custom:public domain')
depends=('common-lisp' 'cl-asdf' 'sqlite' 'cl-iterate' 'cl-cffi')
source=("http://common-lisp.net/project/$pkgname/releases/$pkgname-$pkgver.tar.gz")
md5sums=('a4b54941ae3810691645828613287cf0')

prepare() {
    echo "The code is in public domain so you can basically do with it whatever you want." > LICENSE
}

package() {
    local destination="$pkgdir"/usr/share/common-lisp/source/$pkgname
    local source="$srcdir"/$pkgname-$pkgver

    install -d "$destination"
    install -d "$pkgdir"/usr/share/licenses/$pkgname
    install -d "$pkgdir"/etc/common-lisp/source-registry.conf.d/

    install -m 644 "$source"/*.lisp "$destination"
    install -m 644 "$source"/*.asd "$destination"
    install -m 644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname

    echo "(:directory \"/usr/share/common-lisp/source/$pkgname\")" \
        > "$pkgdir"/etc/common-lisp/source-registry.conf.d/20-$pkgname.conf
}