# http://common-lisp.net/project/babel/releases/babel_0.4.0.tar.gz

_name=babel
pkgname=cl-$_name
pkgver=0.4.0
pkgrel=1
pkgdesc="A charset encoding/decoding library, not unlike GNU libiconv, written in Common Lisp"
arch=('i686' 'x86_64')
url="http://common-lisp.net/project/babel/"
license=('BSD')
depends=('common-lisp' 'cl-asdf' 'cl-trivial-gray-streams'
    'cl-alexandria' 'cl-trivial-features')
source=(http://common-lisp.net/project/$_name/releases/${_name}_$pkgver.tar.gz)
md5sums=('6671b21f4bdca262c8a885d46f29db80')

package()
{
    local destination="$pkgdir"/usr/share/common-lisp/source/$_name
    local source="$srcdir"/${_name}_$pkgver

    install -d "$destination"/src
    install -d "$destination"/tests
    install -d "$pkgdir"/usr/share/licences/$pkgname
    install -d "$pkgdir"/etc/common-lisp/source-registry.conf.d/

    install -m 644 "$source"/src/*.lisp "$destination"/src
    install -m 644 "$source"/tests/*.lisp "$destination"/tests
    install -m 644 "$source"/*.asd "$destination"
    install -m 644 "$source"/COPYRIGHT \
        "$pkgdir"/usr/share/licences/$pkgname

    echo "(:tree \"/usr/share/common-lisp/source/$_name\")" \
        > "$pkgdir"/etc/common-lisp/source-registry.conf.d/20-$_name.conf
}