From 08c336290ed2ebb3446225d11e310bf2d406c31f Mon Sep 17 00:00:00 2001
From: Tom Willemse
Date: Thu, 4 Jul 2024 23:57:28 -0700
Subject: Add configuration for icecat

---
 oni/home/services/gnuzilla.scm | 85 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 85 insertions(+)
 create mode 100644 oni/home/services/gnuzilla.scm

(limited to 'oni/home/services')

diff --git a/oni/home/services/gnuzilla.scm b/oni/home/services/gnuzilla.scm
new file mode 100644
index 0000000..61b9c36
--- /dev/null
+++ b/oni/home/services/gnuzilla.scm
@@ -0,0 +1,85 @@
+(define-module (oni home services gnuzilla)
+  #:use-module ((ice-9 match)
+                #:select (match))
+  #:use-module ((gnu services configuration)
+                #:select (serialize-package
+                          define-configuration))
+  #:use-module ((gnu packages gnuzilla)
+                #:select (icecat))
+  #:use-module ((gnu home services)
+                #:select (service-type
+                          service-extension
+                          home-profile-service-type
+                          home-files-service-type))
+  #:use-module ((guix packages)
+                #:select (package?))
+  #:use-module ((guix gexp)
+                #:select (gexp
+                          mixed-text-file))
+
+  #:export (home-icecat-service-type
+            home-icecat-configuration))
+
+(define (serialize-setting pair)
+  (match pair
+    ((key (? boolean? value))
+     (format #f "user_pref(~s, ~a);" key (if value "true" "false")))
+    ((key (? number? value))
+     (format #f "user_pref(~s, ~a);" key value))
+    ((key (? string? value))
+     (format #f "user_pref(~s, ~s);" key value))))
+
+(define (serialize-alist field value)
+  (string-join (map serialize-setting value) "\n"))
+
+(define (alist? value)
+  (or (null? value)
+      (and (list? value)
+           (list? (car value)))))
+
+(define-configuration home-icecat-configuration
+  (package
+    (package icecat)
+    "Package to use for setting up icecat.")
+  (settings
+   (alist '())
+   "Settings to specify for the generated profile."))
+
+(define (add-icecat-packages config)
+  (list (home-icecat-configuration-package config)))
+
+(define (home-icecat-configuration-files config)
+  `((".mozilla/icecat/profiles.ini"
+     ,(mixed-text-file
+       "profiles.ini"
+       "[Install4F96D1932A9F858E]\n"
+       "Default=default\n"
+       "Locked=1\n"
+       "\n"
+       "[Profile0]\n"
+       "Name=default\n"
+       "IsRelative=1\n"
+       "Path=default\n"
+       "Default=1\n"
+       "\n"
+       "[General]\n"
+       "StartWithLastProfile=1\n"
+       "Version=2\n"))
+    (".mozilla/icecat/default/user.js"
+     ,(mixed-text-file
+       "user.js"
+       (serialize-alist config (home-icecat-configuration-settings config))))))
+
+(define home-icecat-service-type
+  (service-type
+   (name 'home-icecat)
+   (extensions
+    (list (service-extension
+           home-profile-service-type
+           add-icecat-packages)
+          (service-extension
+           home-files-service-type
+           home-icecat-configuration-files)))
+   (compose identity)
+   (default-value (home-icecat-configuration))
+   (description "Install and configure icecat.")))
-- 
cgit v1.2.3-54-g00ecf