;;; linkwave -- Store/retrieve/manage bookmarks
;; Copyright (C) 2012  Tom Willemsen <tom at ryuslash dot org>

;; This program is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; The main program.  For documentation you should consult the
;; README.org and/or any Texinfo documentation provided.

;;; Code:

(declare (uses paths))

(require-extension sqlite3)
(require-library posix srfi-4)

(: string-no-null (string -> string))
(define (string-no-null str)
  (if (and (> (string-length str) 0)
           (char=? (string-ref str (- (string-length str) 1)) #\nul))
      (substring str 0 (- (string-length str) 1))
      str))

(: print-row (string fixnum string string -> void))
(define (print-row url seconds name description)
  (format #t "~a~%  ~a~%  ~a~%  ~a~%~%" (string-no-null name) (string-no-null description)
          (string-no-null url) (seconds->string seconds)))

(define (add-tag db name)
  (execute db "INSERT INTO tag VALUES (?)" name)
  (last-insert-rowid db))

(define (add-bookmark db url name description tags)
  (execute db "INSERT INTO bookmark VALUES (?, STRFTIME('%s'), ?, ?)"
           url name description)
  (let ((bookmark-id (last-insert-rowid db)))
    (for-each (lambda (tag)
                (let ((tag-id '()))
                  (condition-case
                   (set! tag-id (first-result db "SELECT rowid FROM tag WHERE name = ?" tag))
                   (exn (exn sqlite3)
                        (if (eq? (get-condition-property exn 'sqlite3 'status) 'done)
                            (set! tag-id (add-tag db tag))
                            (signal exn))))
                  (execute db "INSERT INTO bookmark_tag VALUES (?, ?)"
                           bookmark-id tag-id)))
              tags)))

(define (url-string? str)
  (and (> (string-length str) 7)
       (or (string= (substring str 0 7) "http://")
           (string= (substring str 0 8) "https://"))))

(define (main args)
  (let ((db (open-database (data-file "linkwave.db"))))
    (if (null? args)
        (for-each-row print-row db "select * from bookmark")
        (cond
         ((url-string? (car args))
          (with-transaction
           db (lambda () (add-bookmark db (car args) (cadr args) (caddr args) (cdddr args)) #t)))
         (else
          (format #t "Unrecognized option: ~a~%" (car args)))))

    (finalize! db #t)))

(main (command-line-arguments))