;;; oni-scheme.el --- Scheme configuration           -*- lexical-binding: t; -*-

;; Copyright (C) 2019  Tom Willemse

;; Author: Tom Willemse <tom@ryuslash.org>
;; Keywords: local
;; Version: 2026.0714.001225
;; Package-Requires: (oni-company oni-paredit rainbow-delimiters geiser geiser-guile)

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; Scheme configuration.

;;; Code:

(require 'geiser)
(require 'geiser-impl)
(require 'geiser-repl)

(defvar oni-scheme-hidden-imports-keymap
  (let ((keymap (make-sparse-keymap)))
    (define-key keymap (kbd "TAB") 'oni-scheme-toggle-import-display)
    keymap))

(defun oni-scheme--auto-fill-mode ()
  "Enable ‘auto-fill-mode’ only for comments."
  (setq-local comment-auto-fill-only-comments t)
  (auto-fill-mode))

(defun oni-scheme-geiser-repl-remove-paredit-newline-keys ()
  "Disable ‘C-j’ and ‘RET’ keybindings from ‘geiser-repl-mode’."
  (let ((oldmap (map-elt minor-mode-map-alist 'paredit-mode))
        (newmap (make-sparse-keymap)))
    (set-keymap-parent newmap oldmap)
    (define-key newmap (kbd "RET") nil)
    (define-key newmap (kbd "C-j") nil)
    (make-local-variable 'minor-mode-overriding-map-alist)
    (push `(paredit-mode . ,newmap) minor-mode-overriding-map-alist)))

(defconst +oni-scheme-import-display+ " …"
  "What to display instead of the scheme imports.")

(defun oni-scheme-toggle-import-display ()
  (interactive)
  (let* ((overlay (seq-find (lambda (o) (overlay-get o 'oni-scheme-hidden-imports))
                            (overlays-at (point))))
         (visiblep (not (string= +oni-scheme-import-display+
                                 (overlay-get overlay 'display)))))
    (overlay-put overlay 'display (if visiblep +oni-scheme-import-display+ nil))))

(defun oni-scheme-hide-guile-imports ()
  "Hide the imports in ‘define-module’."
  (save-excursion
    (let (start end)
      (goto-char (point-min))
      (when (re-search-forward (rx "(" (or "define-module"
                                           "use-modules"))
                               nil t)
        (forward-char (- (length (match-string 0))))
        (setq start (line-end-position))
        (forward-sexp)
        (setq end (1- (point)))
        (dolist (o (overlays-in start end))
          (when (overlay-get o 'oni-scheme-hidden-imports)
            (delete-overlay o)))
        (let ((overlay (make-overlay start end)))
          (overlay-put overlay 'oni-scheme-hidden-imports t)
          (overlay-put overlay 'display +oni-scheme-import-display+)
          (overlay-put overlay 'keymap oni-scheme-hidden-imports-keymap))))))

(add-hook 'scheme-mode-hook 'company-mode)
(add-hook 'scheme-mode-hook 'display-fill-column-indicator-mode)
(add-hook 'scheme-mode-hook 'oni-scheme--auto-fill-mode)
(add-hook 'scheme-mode-hook 'paredit-mode)
(add-hook 'scheme-mode-hook 'rainbow-delimiters-mode)
(add-hook 'scheme-mode-hook 'oni-scheme-hide-guile-imports)

(add-hook 'geiser-repl-mode-hook 'paredit-mode)
;;; Make sure this gets added _after_ ‘paredit-mode’ so that it gets executed
;;; later.
(add-hook 'geiser-repl-mode-hook #'oni-scheme-geiser-repl-remove-paredit-newline-keys 90)

(setq geiser-default-implementation 'guile)

(setq geiser-repl-history-filename
      (expand-file-name "data/geiser-history" user-emacs-directory))

(put 'with-cwd 'scheme-indent-function 1)
(put 'with-env 'scheme-indent-function 1)

;;;###autoload
(add-to-list 'interpreter-mode-alist '("scsh" . scheme-mode))

(modify-syntax-entry ?| "_" scheme-mode-syntax-table)

(provide 'oni-scheme)
;;; oni-scheme.el ends here